Passing Array parameter to Kusto user defined function and doing null check

you could try using set_has_element().

for example:

let T = range x from 1 to 5 step 1
;
let F = (_x: dynamic = dynamic(null)) {
    T
    | where isnull(_x) or set_has_element(_x, x)
    | order by x desc
}
;
F(dynamic([1,2,4]))

Though, please note the following, regarding stored functions: https://docs.microsoft.com/en-us/azure/data-explorer/kusto/query/functions/user-defined-functions#features-that-are-currently-unsupported-by-user-defined-functions

1.

x in (_x) is a valid syntax

let _x = dynamic([1,2,4]);
print   is_2_in_x = 2 in (_x)
       ,is_3_in_x = 3 in (_x)

Fiddle

2.

Figuring out if array is null/empty is complicated and the use of isnull() and/or isempty() is not sufficient for the task.
Please note the 3 last options in the demo below for potential solutions.

let F = (_x_as_str:string = "", _x: dynamic = dynamic(null)) 
{
    print   _x_as_str               = _x_as_str
           ,isnull                  = isnull(_x)
           ,isempty                 = isempty(_x)
           ,array_length            = array_length(_x)
           ,is_1st_null             = isnull(_x[0])
           ,is_1st_empty            = isempty(_x[0])
           ,coalesce_array_length   = coalesce(array_length(_x), 0)
}
;
union   F("dynamic([1,2,4])",dynamic([1,2,4]))
       ,F()
       ,F("dynamic(null)", dynamic(null))
       ,F("dynamic([])" , dynamic([]))

Fiddle