Totals not showing correctly in Power BI Table summing a measure

user_2430171 0
Viewed 115

I have a table summing Meter Hrs. The total is incorrectly showing zero. I need it sum all Meter Hrs values:

enter image description here

Meter Hrs is a measure defined as the following:

Meter Hrs Total = 
        CALCULATE(MIN('Tenna Hours'[total_hours]),LASTDATE('Tenna Hours'[import_date]))
        - CALCULATE(MIN('Tenna Hours'[total_hours]),FIRSTDATE('Tenna Hours'[import_date]))

I thought this summing to zero, might be due to incorrect datatypes. [total_hours] as a datatype of Decimal Number and [import_date] has a datatype of Date/Time.

dax powerbi
1 Answers

Try creating a SUMMARIZEd table:

Meter Hrs Total =
VAR MyTable =
    ADDCOLUMNS(
        SUMMARIZE( 'Tenna Hours', 'Tenna Hours'[Equipment] ),
        "Meter Hrs",
            CALCULATE(
                MIN( 'Tenna Hours'[total_hours] ),
                LASTDATE( 'Tenna Hours'[import_date] )
            )
                - CALCULATE(
                    MIN( 'Tenna Hours'[total_hours] ),
                    FIRSTDATE( 'Tenna Hours'[import_date] )
                )
    )
RETURN
    IF(
        ISFILTERED( 'Tenna Hours'[Equipment] ),
        MINX( MyTable, [Meter Hrs] ),
        SUMX( MyTable, [Meter Hrs] )
    )
user_170077040
Related