Is it possible to modify data in the ingestion mapping using Azure Data Explorer?

A good practice to achieve this is using a staging table and an update policy to propagate the data to the target table:

(1) Create a raw table, where data is initially ingested. This table stores the original json data:

.create table raw (d : dynamic)

(2) Create an ingestion mapping for the raw table:

.create table raw ingestion json mapping "ingest-raw"' [{"column":"d","Properties":{"path":"$"}}]'

(3) Create the table with the transformed data:

.create table measurement (deviceId:string, enqueuedTime:datetime, temperature:real)

(4) Define the data transformation from the raw to the measurement table

.create-or-alter function 
with (docstring = 'update policy for measurement', folder='PBI')
rawtransform()  {
raw
| extend m=todynamic(d.measurement)
| mv-expand (m)
| extend deviceId=tostring(m.header.deviceId), 
enqueuedTime=todatetime(m.header.enqueuedTime), 
temperature=toreal(m.temperature)
| project-away d, m}

(5) Define an update policy definition for the measurement table, with this new ingested data to table raw will be inserted in the measurement table

.alter table measurement policy update @'[{"IsEnabled": true, "Source": 
"raw", "Query": "rawtransform()", "IsTransactional": false, 
"PropagateIngestionProperties": false}]'

For the staging table you can define a shorter caching period, if the data is not queried so often.

Short answer:

Not supported as part of data mappings

Detailed answer:

JSONPath expressions supports $, ., ['property'] or ["property"] and [n].
Mapping transformations adds some additional capabilities around source file info (path & line number), unix-time (transformation to datetime) and transformation of JSON array of properties to dictionary.

Solution:

This logic can be implemented with Update Policy

P.S.

Please note that arrays' indexes start with 0

Demo:

Create a staging table

.create table exampleStg (timestamp:datetime, rawValue:string, Name:string)

// This will keep the staging table empty
.alter-merge table exampleStg policy retention softdelete = 0s

Create a final table

.create table example (timestamp:datetime, rawValue:string, Name:string, Name1:string, Name2:string, Name3:string, Name4:string, Name5:string, Name6:string, Name7:string, Name8:string)

Create a function that is doing the data transformation from the staging table to the final table.
Please note that within the context of update policy, the staging table name stands for a batch of new ingested data and not the entire data.

.create-or-alter function transform_exampleStg_to_example()
{
    exampleStg
    | extend Name_array = split(Name, "_")
    | extend Name1 = tostring(Name_array[0]), Name2 = tostring(Name_array[1]), Name3 = tostring(Name_array[2]), Name4 = tostring(Name_array[3])
    | extend Name5 = tostring(Name_array[4]), Name6 = tostring(Name_array[5]), Name7 = tostring(Name_array[6]), Name8 = tostring(Name_array[7])
    | project-away Name_array
}

Define the update policy

.alter-merge table example policy update @'[{"IsEnabled": true, "Source": "exampleStg", "Query": "transform_exampleStg_to_example()", "IsTransactional": true, "PropagateIngestionProperties": true}]'

.ingest inline into table exampleStg with (format="JSON") <|
{"timestamp":"2022-07-13 13:33:33","rawValue":"Hello","Name":"aaa_bbb_ccc_ddd_eee_fff_ggg_hhh"}
{"timestamp":"2022-07-14 14:44:44","rawValue":"world","Name":"aa_bb_cc_dd_ee_ff_gg_hh"}

.ingest inline into table exampleStg with (format="JSON") <|
{"timestamp":"2022-07-15 15:55:55","rawValue":"!","Name":"a_b_c_d_e_f_g_h"}

exampleStg

example