XQuery: How do I use the results of an inner for-loop to order the results of an outer for-loop?

user_12421217 0
Viewed 45

I am writing an XQuery to process data pulled from two XML documents. The task is to take the words of a series of songs, assign a score to each word, and get the average word score for that song. So far, this works:

<table>
<tr><th>Song Title</th><th>Score</th></tr>
{let $song := $words-sep//song
for $s in $song
     let $word := $s/lyrics-counted/word
     return (<tr><td>{$s/songName/string()}</td><td>{avg(
          for $w in $word
          return ($w/count/data() * $word-score//word[./v/string() = $w/v/string()]/vScore/data())
)}</td></tr>)
}
</table>

Here's the problem: I want to order the output of the songs (the outer for-loop) according to their score (which is only calculated in the inner for-loop). But the inner for-loop appears in the return of the outer for-loop, so I can't use order by in the outer for-loop since it would be ordering by a variable that hasn't been defined or calculated yet. Surely there must be a way to do this, but how? I'm running XPath 3.1 in oXygen, if that helps.

xquery for-loop xpath xml
1 Answers

I think you want e.g.

<table>
<tr><th>Song Title</th><th>Score</th></tr>
{
for $song in $words-sep//song
  let $words := $song/lyrics-counted/word,
      $score := avg(
                 for $word in $words
                 return 
                   $word/count/data() 
                   * $word-score//word[v/string() = $word/v/string()]/vScore/data()
                )
order by $score
return
  <tr>
    <td>{$song/songName/string()}</td>
    <td>{$score}</td>
  </tr>
}
</table>

instead of the used

<table>
<tr><th>Song Title</th><th>Score</th></tr>
{let $song := $words-sep//song
for $s in $song
     let $word := $s/lyrics-counted/word
     return (<tr><td>{$s/songName/string()}</td><td>{avg(
          for $w in $word
          return ($w/count/data() * $word-score//word[./v/string() = $w/v/string()]/vScore/data())
)}</td></tr>)
}
</table>
user_2522280
Related