Snakemake: MissingInputException - Missing input files for rule all

Troy Comi has already answered your question in comments, but I will explain it further.

Indeed, removing double braces will help. The difference between single and double braces is that double braces escape the symbol '{' and '}'. In other words whenever Snakemake encounters a string like this one "{{sample}}/{sample}_phased_illumina_FILT5.vcf.gz" in the output section, it treats {sample} as a wildcard and {{sample}} as a string "{sample}". So it tries to find the files like {sample}/saturna_phased_illumina_FILT5.vcf.gz which it definitely fails to find.

The problem is quite different in case of using this string in the expand function:

expand("{{sample}}/{sample}_phased_illumina_FILT5_{chrom}.vcf", sample=samples, chrom=chroms)

Here the function replaces the {sample} and {chrom} with the values from the lists you provide as parameters samples and chroms. The {{sample}} is being converted to the string "{sample}", but that is not the end of the story. This result of the conversion "{sample}" is being treated as a wildcard {sample}. For example, consider the rule:

samples = ['12NAE3', '15NOH7']
chroms = ['chr01','chr02']

rule ConcatVCF:
    input:
        expand("{{sample}}/{sample}_phased_illumina_FILT5_{chrom}.vcf", sample=samples, chrom=chroms)
    output:
        "{{sample}}/{sample}_phased_illumina_FILT5.vcf"

This rule is equivalent to this one, where {wildcard} is actual wildcard (so the name is irrelevant), and {{sample}} is a string "{sample}":

rule ConcatVCF:
    input:
        "{wildcard}/12NAE3_phased_illumina_FILT5_chr01.vcf",
        "{wildcard}/12NAE3_phased_illumina_FILT5_chr02.vcf",
        "{wildcard}/15NOH7_phased_illumina_FILT5_chr01.vcf",
        "{wildcard}/15NOH7_phased_illumina_FILT5_chr02.vcf"
    output:
        "{{sample}}/{wildcard}_phased_illumina_FILT5.vcf"

That is definitely not what you meant. Removing double braces you make this rule equivalent to:

rule ConcatVCF:
    input:
        "12NAE3/12NAE3_phased_illumina_FILT5_chr01.vcf",
        "12NAE3/12NAE3_phased_illumina_FILT5_chr02.vcf",
        "15NOH7/15NOH7_phased_illumina_FILT5_chr01.vcf",
        "15NOH7/15NOH7_phased_illumina_FILT5_chr02.vcf"
    output:
        "{wildcard}/{wildcard}_phased_illumina_FILT5.vcf"

Based on your expected commands, here is my attempt at refactoring your workflow. I've commented to explain the changes.

# moved shell prefix to envmodules directive
# https://snakemake.readthedocs.io/en/stable/snakefiles/deployment.html#using-environment-modules
# that's better for if you need a different set of modules later

reference = "/srv/KLN/users/esv/Reference/DM_v6/DM_1-3_516_R44_potato_genome_assembly.v6.1.fa"
samples= ['12NAE3', '15NOH7', 'avarna', 'avenue', 'Kuras', 'saturna', 'seresta', 'stratos', 'verdi', 'wotan', 'ydun']
chroms= [f'chr{chrom:02}' for chrom in range(1, 13)]

# place filenames together or (better) in a config.yaml
phased_output = '{sample}/{sample}_phased_illumina_FILT5.vcf.gz'
variants = '/srv/KLN/users/esv/KRISPS/snakemake/2110_variantcalling/results/variants/filtered/FILT5/variants_FILT5_{chrom}.vcf'
sample_bam = '/srv/KLN/users/esv/KRISPS/Data/Illumina/DM_v6/BAM/{sample}.bam'
temp_vcf = 'temp/{sample}/{sample}_phased_illumina_FILT5_{chrom}.vcf'
split_vcf = '{sample}/{sample}_phased_illumina_FILT5_{chrom}.vcf'


# don't repeat yourself with sample names or phased output
# using expand makes it easier to add new samples later or change your
# filename
rule all:
    input:  
        expand(phased_output, sample=samples)

# using variables for filenames makes rules clearer
# Based on your sample, I think you should pass in wildcards.chrom
# instead of the chroms list
# For shell, I like to format the calls with an option per line
# it makes it easier to see all options and change or remove them.
# snakemake will combine all the lines so note the spaces at the end of
# each line!
rule HaplotypeCalling:
    input:
        reference = reference,
        vcf = variants,
        bam = sample_bam,
    output:
        temp_vcf
    envmodules:
        'whatshap/1.1-foss-2020b-Python-3.8.6'
    shell:
        "whatshap polyphase "
            "--ploidy 4 "
            "-o {output} "
            "--sample {wildcards.sample} "
            "--chromosome {wildcards.chroms}"
            "--reference {input.reference} {input.vcf} {input.bam} "

# options before arguments
rule SplitVCF:
    input:
        temp_vcf
    output:
        split_vcf
    envmodules:
        'BCFtools/1.11-GCC-10.2.0'
    shell:
        "bcftools view "
            "-s {wildcards.sample} "
            "-o {output} "
            "{input}"
        
# use output type option of bcf tools to skip the bgzip step
rule ConcatVCF:
    input:
        expand(split_vcf, chrom=chroms, allow_missing=true)
    output:
        phased_output
    envmodules:
        'BCFtools/1.11-GCC-10.2.0'
    shell:
        "bcftools concat "
            "-o {output} "
            "-O z "  # compressed vcf output
            "{input} "

Not tested but that's my first pass at it!

Spend some time with the rules page on the documentation and work through the tutorial. Wildcards are important but really subtle. Here's some materials for a workshop I give. It's a little dated but the core material is still good.