How to generate a DateTime range by step of 5 minutes?

user_5829526 0
Viewed 870

How to generate a DateTime range by step of 5 minutes? The following is the output:

2022-02-13 00:00:00, 2022-02-13 00:05:00
2022-02-13 00:05:00, 2022-02-13 00:10:00
2022-02-13 00:10:00, 2022-02-13 00:15:00
2022-02-13 00:15:00, 2022-02-13 00:20:00
...
2022-02-13 23:45:00, 2022-02-13 23:50:00
2022-02-13 23:50:00, 2022-02-13 23:55:00
2022-02-13 23:55:00, 2022-02-14 00:00:00
raku datetime
4 Answers

Sequence operator can be used

# when to start when to finish
my $start = DateTime.now.truncated-to("day");
my $end   = $start.later(:1day);

# after start, add 5 mins repeatedly, and stop when end is exceeded
say $start, *.later(:5minutes) ... * >= $end;
Admin1

Use the Interval module.

use Interval;
my $dt = Interval[300].new(time);
say $dt++ for ^5; 

2022-02-13T15:29:03Z
2022-02-13T15:34:03Z
2022-02-13T15:39:03Z
2022-02-13T15:44:03Z
2022-02-13T15:49:03Z
user_74244700 
my $dt = Date.today.DateTime;

$dt.clone: formatter => { .yyyy-mm-dd ~ q{ } ~ .hh-mm-ss }\
andthen $_, *.later(:5minute) ... * eqv $dt.later(:1day)  
andthen .rotor: 2 => -1 
andthen .map: *.join(q{, }).put
user_54580860

I come up with another solution:

sub MAIN() {
    my $fmt = {sprintf "%04d-%02d-%02d %02d:%02d:%02d", .year, .month, .day, .hour, .minute, .second};

    my @dates = gather given Date.today {
        my $current-datetime = .DateTime;
        while $current-datetime <= .succ.DateTime {
            take $current-datetime;
            $current-datetime = $current-datetime + Duration.new(300.0);
        }
    }

    for @dates.rotor(2 => -1) {
        printf("%s, %s\n", .[0].clone(formatter => $fmt), .[1].clone(formatter => $fmt));
    }
}

thanks @wamba for the clone method.

user_58295260
Related