Williams Fractals plot not consistent with strategy results

Question

I am doing a very simple test using the Williams Fractal indicator that I copied directly from the standard one in Tradingview "as is".

I am trying to enter the trade when downFractal is true, exit it when upFractal is true.

The results of the strategy are completely inconsistent with what they should be as for the plotting and, for the love of me, I honestly cannot understand why. Maybe I am not using boolean variables right?

strategy("1d fractals", overlay=true, default_qty_type=strategy.cash, default_qty_value=100)


i_startTime = input.time(defval = timestamp("01 Jan 2021 00:00 +0000"), title = "Start Time")
inDateRange = time >= i_startTime


////////////////////////////////// FRACTALS ///////////////////////////////////////////


n = input.int(title="Periods", defval=2, minval=2)


// UpFractal
bool upflagDownFrontier = true
bool upflagUpFrontier0 = true
bool upflagUpFrontier1 = true
bool upflagUpFrontier2 = true
bool upflagUpFrontier3 = true
bool upflagUpFrontier4 = true

for i = 1 to n
    upflagDownFrontier := upflagDownFrontier and (high[n-i] < high[n])
    upflagUpFrontier0 := upflagUpFrontier0 and (high[n+i] < high[n])
    upflagUpFrontier1 := upflagUpFrontier1 and (high[n+1] <= high[n] and high[n+i + 1] < high[n])
    upflagUpFrontier2 := upflagUpFrontier2 and (high[n+1] <= high[n] and high[n+2] <= high[n] and high[n+i + 2] < high[n])
    upflagUpFrontier3 := upflagUpFrontier3 and (high[n+1] <= high[n] and high[n+2] <= high[n] and high[n+3] <= high[n] and high[n+i + 3] < high[n])
    upflagUpFrontier4 := upflagUpFrontier4 and (high[n+1] <= high[n] and high[n+2] <= high[n] and high[n+3] <= high[n] and high[n+4] <= high[n] and high[n+i + 4] < high[n])
flagUpFrontier = upflagUpFrontier0 or upflagUpFrontier1 or upflagUpFrontier2 or upflagUpFrontier3 or upflagUpFrontier4

upFractal = (upflagDownFrontier and flagUpFrontier)


// downFractal
bool downflagDownFrontier = true
bool downflagUpFrontier0 = true
bool downflagUpFrontier1 = true
bool downflagUpFrontier2 = true
bool downflagUpFrontier3 = true
bool downflagUpFrontier4 = true

for i = 1 to n
    downflagDownFrontier := downflagDownFrontier and (low[n-i] > low[n])
    downflagUpFrontier0 := downflagUpFrontier0 and (low[n+i] > low[n])
    downflagUpFrontier1 := downflagUpFrontier1 and (low[n+1] >= low[n] and low[n+i + 1] > low[n])
    downflagUpFrontier2 := downflagUpFrontier2 and (low[n+1] >= low[n] and low[n+2] >= low[n] and low[n+i + 2] > low[n])
    downflagUpFrontier3 := downflagUpFrontier3 and (low[n+1] >= low[n] and low[n+2] >= low[n] and low[n+3] >= low[n] and low[n+i + 3] > low[n])
    downflagUpFrontier4 := downflagUpFrontier4 and (low[n+1] >= low[n] and low[n+2] >= low[n] and low[n+3] >= low[n] and low[n+4] >= low[n] and low[n+i + 4] > low[n])
flagDownFrontier = downflagUpFrontier0 or downflagUpFrontier1 or downflagUpFrontier2 or downflagUpFrontier3 or downflagUpFrontier4

downFractal = (downflagDownFrontier and flagDownFrontier)


//////////////////////////////////////////////// STRATEGY CONDITIONS //////////////////////////////////////////////// 

longEntry = downFractal
exitLong = upFractal

inTradeLong = strategy.position_size > 0
notInTradeLong = strategy.position_size <= 0


if (longEntry and inDateRange)
    strategy.entry("Long", strategy.long)

if ((exitLong) and inTradeLong)
    strategy.close("Long")
 
 
//////////////////////////////////////////////// PLOTTING ////////////////////////////////////////////////    

bgcolor(notInTradeLong ? color.new(color.red, 80) : color.new(color.green, 80))
plotshape(downFractal, "downFractal", style=shape.triangledown, location=location.belowbar, offset=-n, color=#F44336, size = size.small)
plotshape(upFractal, "upFractal", style=shape.triangleup,   location=location.abovebar, offset=-n, color=#009688, size = size.small)

user_7209631 · Answer

plotshape(downFractal, "downFractal", style=shape.triangledown, location=location.belowbar, offset=-n, color=#F44336, size = size.small)
plotshape(upFractal, "upFractal", style=shape.triangleup,   location=location.abovebar, offset=-n, color=#009688, size = size.small)

That is because those fractals are plotted with an offset. You cannot enter exactly when the fractals occur because it waits for n bars to confirm and when it plots, it goes back n bars and plots the shape there. So, when you want to enter, you are already n bars late.

One way to see this is, remove the offset parameter from those plotshape() functions. Then you will see when the fractals are confirmed and your buy and sell orders actually follows the confirmation.

Williams Fractals plot not consistent with strategy results

1 Answers