What is the simplest way to find files modified within the past hour?

user_1461307 0
Viewed 144

This question is a special case of "in perl, what is the simplest way to find files modified within a given time interval?" and the solution below could easily be generalized. In bash, we can type

> find . -mtime -1h

but I want to do this in pure perl. The code below does this. It explicitly runs stat on each file.

Is there any way that this can be made simpler or more elegant? Granted, this is slower than the bash command; I am not trying to compete with bash for efficiency. I'm just trying to do it purely in perl.

#!/usr/bin/env perl 
use strict; use warnings;
use File::Find;
my $invocation_seconds=time;
my $interval_left =  $invocation_seconds - (60 * 60); # one hour ago
my $count_all=0;
my @selected;
find(
    sub
    {
        $count_all++;
        my $mtime_seconds=(stat($_))[9];
        return unless defined $mtime_seconds; # if we edit files while running current script, this can be undef on occasion 
        return unless ($mtime_seconds>$interval_left);
        push@selected,$File::Find::name;
    }
    ,
    '.', # current directory 
);
my $end_seconds=time;
my $totalselected=scalar@selected;
print ($_,"\n",)for@selected;
print $^V; print " <- perl version\n";
print 'selected ',$totalselected, '/',$count_all,' in ',($end_seconds-$invocation_seconds),' seconds',"\n";
find perl
2 Answers
use File::Find::Rule qw( );

my $cutoff = time - 60*60;

say for File::Find::Rule->mtime( ">=$cutoff" )->in( "." );
user_5899240

Following demo sample code utilizes function stat to filter out files modified in last hour.

Note: with slight modification the code can be adopted for recursion

use strict;
use warnings;
use feature 'say';

use constant STAMP => time() - 60*60;
use constant MTIME => 9;

my $dir = shift || '.';
my @files;

(stat($_))[MTIME] > STAMP && push @files, $_
    for glob("$dir/*");

say "
Files changes in last hour
--------------------------";
say for @files;

Recursive version which reports lookup time

use strict;
use warnings;
use feature 'say';

use Time::HiRes qw(gettimeofday tv_interval);

use constant STAMP => time() - 60*60;
use constant MTIME => 9;

my $dir   = shift || '.';

my $start = [gettimeofday];
my $found = lookup($dir);
my $elapsed = tv_interval($start)

say "
Elapsed lookup time: $elapsed seconds";

say "
Files changed in last hour
--------------------------";
say for @$found;

exit 0;

sub lookup {
    my $dir  = shift;
    my $files;

    for my $item ( glob("$dir/*") ) {
        if( -d $item ) {
            my $matched = lookup($item);
            push @$files, $_ for @{$matched};
        }
        next unless (stat($item))[MTIME] > STAMP;
        push @$files, $item if -f $item;
    }

    return $files;
}
user_123133090
Related