Perl eval scope

user_5128398 0
Viewed 110

According to perldoc, String Eval should be performed in the current scope. But the following simple test seems to contradict this.

We need the following two simple files to set up the test. Please put them under the same folder.

test_eval_scope.pm

package test_eval_scope;

use strict;
use warnings;

my %h = (a=>'b');

sub f1 {
   eval 'print %h, "\n"';

   # print %h, "\n";   # this would work
   # my $dummy = \%h;  # adding this would also work
}

1

test_eval_scope.pl

#!/usr/bin/perl

use File::Basename;
use lib dirname (__FILE__);
use test_eval_scope;

test_eval_scope::f1();

When I run the program, I got the following error

$ test_eval_scope.pl
Variable "%h" is not available at (eval 1) line 1.

My question is why the variable %h is out of scope.

I have done some modification, and found the following:

  1. If I run without eval(), as in the above comment, it will work. meaning that %h should be in the scope.
  2. If I just add a seemingly useless mentioning in the code, as in the above comment, eval() will work too.
  3. If I combine pl and pm file into one file, eval() will work too.
  4. If I declare %h with 'our' instead of 'my', eval() will work too.

I encountered this question when I was writing a big program which parsed user-provided code during run time. I don't need solutions as I have plenty workarounds above. But I cannot explain why the above code doesn't work. This affects my perl pride.

My perl version is v5.26.1 on linux.

Thank you for your help!

perl eval scope
1 Answers

Subs only capture variables they use. Since f1 doesn't use %h, it doesn't capture it, and %h becomes inaccessible to f1 after it goes out of scope when the module finishes executing.

Any reference to the var, including one that's optimized away, causes the sub to capture the variable. As such, the following does work:

sub f1 {
   %h if 0;
   eval 'print %h, "\n"';
}

Demo:

$ perl -M5.010 -we'
   {
      my $x = "x";
      sub f {          eval q{$x} }
      sub g { $x if 0; eval q{$x} }
   }

   say "f: ", f();
   say "g: ", g();
'
Variable "$x" is not available at (eval 1) line 1.
Use of uninitialized value in say at -e line 8.
f:
g: x
user_5899240
Related