Having issues with a button in my code that is meant to cycle through many speed multipliers

This part of your logic looks overly complex and error prone:

if(slowDown == 12){
      slowDown = 6;
    }
    if(slowDown == 6){
      slowDown = 4;
    }
    if(slowDown == 4){
      slowDown = 3;
    }
    if(slowDown == 3){
      slowDown = 2;
    }
    if(slowDown == 2){
      slowDown = 12;
    }

A basic example is if slowDown is 6 you set it 4, however in the next condition you check if it's 4 and change it to 3 so because it was 6 not only it goes to 4 but immediately after goes to 3. All your condition trickle down and you end up at 12 in a loop.

Try it out:

if(mouseX > xposSpeed && mouseX < xposSpeed + speedWidth && mouseY > yposSpeed && mouseY < yposSpeed + speedWidth){
    println("before", slowDown);
    if(slowDown == 12){
      slowDown = 6;
    }
    if(slowDown == 6){
      slowDown = 4;
    }
    if(slowDown == 4){
      slowDown = 3;
    }
    if(slowDown == 3){
      slowDown = 2;
    }
    if(slowDown == 2){
      slowDown = 12;
    }
    println("after", slowDown);
  }

The simplest I can think of is to just set slowDown to a value:

if(mouseX > xposSpeed && mouseX < xposSpeed + speedWidth && mouseY > yposSpeed && mouseY < yposSpeed + speedWidth){
    slowDown = 1;
  }

If you want multiple speed multipliers maybe you meant to use a switch: ?

if(mouseX > xposSpeed && mouseX < xposSpeed + speedWidth && mouseY > yposSpeed && mouseY < yposSpeed + speedWidth){
    println("before", slowDown);
    switch(slowDown){
      case 12:
        slowDown = 6;
        break;
      case 6:
        slowDown = 4;
        break;
      case 4:
        slowDown = 3;
        break;
      case 3:
        slowDown = 2;
        break;
      case 2:
        slowDown = 12;
        break;
    }
    println("after", slowDown);
  }

In terms of actual behaviour, based on the button labels if looks looks like you want to cycle through speed presets: 1x, 2x, 3x, 4x then back to 1x.

Alternatively you could manage an array of preset options and simply increment (and loop) an index. Optionally you could also use a presets text labels array.

For example:

int speedPresetIndex = 0;
int[] speedPresetValues = {12, 6, 4, 3, 2};
String[] speedPresetLabels = {"1x","2x","3x","4x",""};
...
if(mouseX > xposSpeed && mouseX < xposSpeed + speedWidth && mouseY > yposSpeed && mouseY < yposSpeed + speedWidth){
    // increment index (looping back to start using %)
    speedPresetIndex = (speedPresetIndex + 1) % speedPresetValues.length; 
    // update slowDown based on preset
    slowDown = speedPresetValues[speedPresetIndex];
  }
...
text(speedPresetLabels[speedPresetIndex], xposSpeed + (speedWidth/2), yposSpeed + (speedWidth/1.4));

Here's modified version of your code with the above changes:

void setup() {
   size(550, 615);
   pixelDensity(2);
   frameRate(60);
   println(colour.length, colour[0].length);
}

int speedPresetIndex = 0;
int[] speedPresetValues = {12, 6, 4, 3, 2};
String[] speedPresetLabels = {"1x","2x","3x","4x",""};


//initial array, set as 2 glider guns ----------------------------
boolean[][] colour =  {{false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false, true, true,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false, true,false,false, true,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false, true,false, true,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false, true,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false, true,false,false,false, true,false,false, true, true, true,false,false,false,false,false,false,false,false,false,false, true,false,false,false,false,false,false, true, true,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false, true,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false, true,false,false,false,false,false,false, true, true,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false, true, true,false,false,false,false, true,false,false,false,false, true,false,false,false,false,false,false,false, true, true,false,false, true,false,false, true,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false, true, true,false,false,false,false,false, true,false,false,false,false,false,false,false, true,false, true,false,false, true,false,false, true, true,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false, true,false,false,false, true,false,false,false,false,false, true, true, true,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false, true,false, true,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false, true,false, true,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false, true, true, true,false,false,false,false,false, true,false,false,false, true,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false, true, true,false,false, true,false,false, true,false, true,false,false,false,false,false,false,false, true,false,false,false,false,false, true, true,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false, true,false,false, true,false,false, true, true,false,false,false,false,false,false,false, true,false,false,false,false, true,false,false,false,false, true, true,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false, true, true,false,false,false,false,false,false, true,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false, true,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false, true, true,false,false,false,false,false,false, true,false,false,false,false,false,false,false,false,false,false, true, true, true,false,false, true,false,false,false, true,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false, true,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false, true,false, true,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false, true,false,false, true,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false, true, true,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false},
                      {false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false,false}
};
//boolean[][] colour = new boolean[50][50];
//----------------------------------------------------------------

//game variables -------------------------------------------------
int xposGame = 25;
int yposGame = 25;
int[] arraySize = {50, 50};
int slowDown = 4;
int speedMultiplier = slowDown;
//----------------------------------------------------------------

//play button variables ------------------------------------------
int xposPlay = xposGame;
int yposPlay = 550;
int playWidth = 40;
boolean playActive = false;
//----------------------------------------------------------------

//clear button variables -----------------------------------------
int clearWidth = 40;
int xposClear = 485;
int yposClear = 550;
//----------------------------------------------------------------

//step button variables ------------------------------------------
int stepWidth = 40;
int xposStep = xposGame + xposPlay + 25;
int yposStep = 550;
//----------------------------------------------------------------

//speed multiplier button variables ------------------------------
int speedWidth = 40;
int xposSpeed = xposGame + xposPlay + xposStep;
int yposSpeed = 550;
//----------------------------------------------------------------

//clear the board ------------------------------------------------
void clearArr(){
  for(int i = 0; i < arraySize[0]; i++){
    for(int j = 0; j < arraySize[1]; j++){
      colour[i][j] = false;
    }
  }
}
//----------------------------------------------------------------

//iteration function ---------------------------------------------
void iteration(){
  
 //counter for # of neighboring cells
 int neighborNum = 0;
  
 //next generations array
 boolean[][] newColour =  new boolean[arraySize[0]][arraySize[1]];
  
 //read the current generation's array
 for(int i = 0; i < arraySize[0]; i++){
   for(int j = 0; j < arraySize[1]; j++){
      
    //search all values around the cell (excluding those outside the array) and count how many neighbors are alive
    if(i != -0){
      if(j != 0){
        if(colour[i-1][j-1]==true){neighborNum++;}
      }
      if(colour[i-1][j]==true){neighborNum++;}
      if(j != arraySize[1]-1){
        if(colour[i-1][j+1]==true){neighborNum++;}
      }
    }
      
    if(j != 0){
      if(colour[i][j-1]==true){neighborNum++;}
    }
    if(j != arraySize[1]-1){
      if(colour[i][j+1]==true){neighborNum++;}
    }
      
    if(i != arraySize[0]-1){
      if(j != 0){
        if(colour[i+1][j-1]==true){neighborNum++;}
      }
      if(colour[i+1][j]==true){neighborNum++;}
      if(j != arraySize[1]-1){
        if(colour[i+1][j+1]==true){neighborNum++;}
      }
    }
        
    //check if the current cell is alive. if it has 2-3 neighbors, it survives, else it doesnt
    if(colour[i][j]==true){
      if(neighborNum==3||neighborNum==2){
        newColour[i][j] = true;
      }
      else{
        newColour[i][j] = false;
      }
    }
        
    //check if the current cell is dead. if it has 3 neighbors, birth it next round
    if(colour[i][j]==false){
      if(neighborNum==3){
        newColour[i][j] = true;
      }
      else{
        newColour[i][j] = false;
      }
    }
       
    //set the number of neighbors on the current cell to 0 for the next cell
    neighborNum = 0;
   }
 }
  
  //set the new array to be the current array
  colour = newColour;
}
//----------------------------------------------------------------

//iteration drawing function -------------------------------------
void drawIteration(){
  for(int i = 0; i < arraySize[0]; i++){
    for(int j = 0; j < arraySize[1]; j++){
      if(colour[i][j] == true){
        fill(255);
      }
      else{fill(0);}
      strokeWeight(2);
      stroke(50);
      rect(10*j+xposGame, 10*i+yposGame, 10, 10);
    }
  }
}
//----------------------------------------------------------------

//play/pause button function -------------------------------------
void drawPlay(){
  noStroke();
  fill(0);
  rect(xposPlay, yposPlay, playWidth, playWidth, 5);
  fill(255);
  if(!playActive){
    triangle(xposPlay + (playWidth/3), yposPlay + (playWidth/3.3), xposPlay + (playWidth/3), yposPlay + playWidth - (playWidth/3.3), xposPlay + (playWidth*3.5/5), yposPlay + (playWidth/2));
  }
  if(playActive){
    rect(xposPlay + (playWidth/3), yposPlay + (playWidth/3.3), playWidth/9, playWidth-(2*(playWidth/3.3)), 2);
    rect(xposPlay + playWidth - (playWidth/3) - (playWidth/9), yposPlay + (playWidth/3.3), playWidth/9, playWidth-(2*(playWidth/3.3)), 2);
  }
}
//----------------------------------------------------------------

//clear button function ------------------------------------------
void drawClear(){
  noStroke();
  fill(0);
  rect(xposClear, yposClear, clearWidth, clearWidth, 5);
  strokeWeight(clearWidth/9);
  stroke(255);
  line(xposClear+clearWidth/3, yposClear + clearWidth/3, xposClear + 2 * clearWidth/3, yposClear + 2 * clearWidth/3);
  line(xposClear+clearWidth/3, yposClear + 2 * clearWidth/3, xposClear + 2 * clearWidth/3, yposClear + clearWidth/3);
}
//----------------------------------------------------------------

//step button function -------------------------------------------
void drawStep(){
  noStroke();
  fill(0);
  rect(xposStep, yposStep, stepWidth, stepWidth, 5);
  strokeWeight(stepWidth/9);
  stroke(255);
  line(xposStep + stepWidth/3, yposStep + stepWidth/3, xposStep + (stepWidth*3.5/5), yposStep + (stepWidth/2));
  line(xposStep + stepWidth/3, yposStep + 2*stepWidth/3, xposStep + (stepWidth*3.5/5), yposStep + (stepWidth/2));
}
//----------------------------------------------------------------

//speed multiplier button ----------------------------------------
void drawSpeed(){
  noStroke();
  fill(0);
  rect(xposSpeed, yposSpeed, speedWidth, speedWidth, 5);
  fill(255);
  textAlign(CENTER);
  textSize(25);
  text(speedPresetLabels[speedPresetIndex], xposSpeed + (speedWidth/2), yposSpeed + (speedWidth/1.4));
}
//----------------------------------------------------------------

//all mousePressed events ----------------------------------------
void mousePressed(){
  
  //play button
  if(mouseX > xposPlay && mouseX < xposPlay + playWidth && mouseY > yposPlay && mouseY < yposPlay + playWidth){
    playActive = !playActive;
  }
  
  //clear button
  if(mouseX > xposClear && mouseX < xposClear + clearWidth && mouseY > yposClear && mouseY < yposClear + clearWidth){
    clearArr();
    playActive = false;
  }
  
  //step button
  if(mouseX > xposStep && mouseX < xposStep + stepWidth && mouseY > yposStep && mouseY < yposStep + stepWidth){
    iteration();
    playActive = false;
  }
  
  //speed multiplier button
  if(mouseX > xposSpeed && mouseX < xposSpeed + speedWidth && mouseY > yposSpeed && mouseY < yposSpeed + speedWidth){
    // increment index (looping back to start using %)
    speedPresetIndex = (speedPresetIndex + 1) % speedPresetValues.length; 
    // update slowDown based on preset
    slowDown = speedPresetValues[speedPresetIndex];
  }
  
  //adding cells
  if(!playActive && mouseX > xposGame && mouseX < xposGame + 10*arraySize[0] && mouseY > yposGame && mouseY < yposGame + 10*arraySize[1]){
      colour[(mouseY-yposGame)/10][(mouseX-xposGame)/10] = !colour[(mouseY-yposGame)/10][(mouseX-xposGame)/10];
  }
}
//----------------------------------------------------------------

void draw() {
  background(50);
  noStroke();
  fill(50);
  
  drawPlay();
  drawClear();
  drawStep();
  drawSpeed();
  
  if(speedMultiplier == 0){
    if(playActive){ 
      iteration();
    }
    speedMultiplier = slowDown;
  }
  
  speedMultiplier --;
  
  drawIteration();
}

Hopefully this solves your main question.

Additionally I have a few suggestions that could be helpful:

• avoid repeating yourself in code. all mouse / button rectangle boundary checks could be encapsulate the logic in a reusable function. (If class at school went over classes you could implement and reuse a Button class). You can see example in this answer. Even though it's in p5.js the syntax is very similar.
• again, if classes were taught, the 2D CA could be encapsulated into a re-usable class
• this is more of a nice to have suggestion: instead of the large 2D boolean array being manually defined like that, you could potentially use a .png image where true is marked as white pixels on a black background. With this approach a future version could potentially not only draw but also save / load 2D CA configurations.

The rest is not bad at all (fairly clean code, consistent naming, etc.) ! Nice work!