separates the string and display just first value

One way to handle this is with Regular Expressions:

Option Explicit

Private Sub Test()
   MsgBox ExtractFirstNumber("KeyNo = ,16,17,18")
   MsgBox ExtractFirstNumber("KeyNo = 16,17,18")
End Sub

Private Function ExtractFirstNumber(ByVal Value As String) As String
   Dim regex As regExp
   Dim matches As MatchCollection

   Set regex = New regExp
   regex.Pattern = "\d+"
   regex.Global = True

   If regex.Test(Value) Then
      Set matches = regex.Execute(Value)
      ExtractFirstNumber = matches(0)
   End If
End Function

The idea of the SplitAndDisplay() code below is the following:

• split by separator and write the result to myArr;
• loop from lbound(myArr) to ubound(myArr) - 1, to make sure that there is always a next item;
• if the splitAfter() is found, then display the next item;
• if not, return -1;

Sub Split16()

    Dim textInput As String
    textInput = "KeyNo = ,16,17,18"
    
    Dim result As String
    result = SplitAndDisplay(textInput, ",", "=")
    Debug.Print result
        
End Sub

Public Function SplitAndDisplay(textInput As String, mySeparator As String, splitAfter As String)
    
    Dim myArr As Variant
    myArr = Split(textInput, mySeparator)
    
    Dim i As Long
    
    For i = LBound(myArr) To UBound(myArr) - 1
        If InStr(myArr(i), "=") Then
            SplitAndDisplay = myArr(i + 1)
            Exit Function
        End If
    Next i
    
    SplitAndDisplay = -1
    
End Function

It seems that you want the 16 whether there is a comma following the "=" or not. If the comma is absent, just put it in and then use Split():

Sub splittt()
    s = "KeyNo = ,16,17,18"
    If InStr(s, "= ,") = 0 Then
        s = Replace(s, "= ", "= ,")
    End If
    
    arr = Split(s, ",")
    MsgBox arr(1)
End Sub