Unix: File have 28 columns separated by space, print column 8 unique values with sum of column 16 to column28

With GNU awk, you could try following. Written and tested with your shown samples.

awk -v FPAT='"[^"]+"|[^"]*' '
{
  sum=0
  num=split($NF,arr," ")
  for(i=1;i<=num;i++){
    sum+=arr[i]
  }
  gsub(/"/,"",$15)
  print $15,sum
}
' Input_file

Explanation: Adding detailed explanation for above.

awk -v FPAT='"[^"]+"|[^"]*' '  ##Starting awk program from here, setting FPAT to set fields as per requirement.
{
  sum=0                        ##Nullifying sum here.
  num=split($NF,arr," ")       ##Splitting last field into array here.
  for(i=1;i<=num;i++){         ##Traversing through all elements of arr here.
    sum+=arr[i]                ##Creating sum from array elements.
  }
  gsub(/"/,"",$15)             ##Removing all " here
  print $15,sum                ##Printing 15 field along with sum here.
}
' Input_file                   ##mentioning Input_file name here.

Output will be as follows:

0ICPRP900 0.006641
0ICPRP 900 0.01
0ICPRP A&B_900 0.641

You really have there is a form of CSV and it would serve well to use a proper parser for CSV. It is a surprisingly complex format...

The lightest weight CSV parser commonly available at the command line is Ruby (but Python, Perl work well too...)

Here is a Ruby:

ruby  -r csv -lane '
   BEGIN{ options={:col_sep=>" ", :quote_char=>"\""} }
   CSV.parse($_, **options)
    { |r| puts "#{r[7]} #{r[18..27].inject(0){|s,x| s+x.to_f}}" }' file

Prints:

0ICPRP900 0.006641
0ICPRP 900 0.01
0ICPRP A&B_900 0.641

Using any awk:

$ awk -F'"' '{n=split($31,f," "); sum=0; for (i=4; i<=n; i++) sum+=f[i]; print $16, sum}' file
0ICPRP900 0.006641
0ICPRP 900 0.01
0ICPRP A&B_900 0.641

Or using GNU awk for FPAT and gensub():

$ awk -v FPAT='"[^"]*"|[^ ]+' '{sum=0; for (i=19; i<=NF; i++) sum+=$i; print gensub(/"/,"","g",$8), sum}' file
0ICPRP900 0.006641
0ICPRP 900 0.01
0ICPRP A&B_900 0.641

or if by unique column8 you mean you want to sum the values for multiple occurrences of the same $8 value across the input file you can do either of:

any awk:

awk -F'"' '
    {
        n = split($31,f," ")
        for (i=4; i<=n; i++) {
            sum[$16] += f[i]
        }
    }
    END {
        for (key in sum) {
            print key, sum[key]
        }
    }
' file

GNU awk:

awk -v FPAT='"[^"]*"|[^ ]+' '
    {
        for (i=19; i<=NF; i++) {
            sum[gensub(/"/,"","g",$8)] += $i
        }
    }
    END {
        for (key in sum) {
            print key, sum[key]
        }
    }
' file