Terraform merge list of maps

Question

My input is as below:

list_groups = [
 {
     dev-api = {
         envs  = [
             "dev-eu-1",
             "dev-eu-2",
          ]
         hosts = [
             "dev-api-eu1",
             "dev-api-eu2",
          ]
      }
  },
 {
     dev-api = {
         envs  = [
             "dev-us-1",
             "dev-us-2",
          ]
         hosts = [
             "dev-api-us1",
             "dev-api-us2",
          ]
      }
  },
]

I am using merge as below:

output "map_groups" {  
    value = merge(var.list_groups...)
}

And the output I get is :

map_groups = {
 dev-api = {
     envs  = [
         "dev-us-1",
         "dev-us-2",
      ]
     hosts = [
         "dev-api-us1",
         "dev-api-us2",
      ]
  }
}

But I need the output to be:

map_groups = {
 dev-api = {
     envs  = [
         "dev-us-1",
         "dev-us-2",
         "dev-eu-1",
         "dev-eu-2"
      ]
     hosts = [
         "dev-api-us1",
         "dev-api-us2",
         "dev-api-eu1",
         "dev-api-eu2"
      ]
  }
}

I understand the merge is eating up one of the entries because the key is the same but if it could somehow merge the entries/elements, that'll be great.

user_248823 · Answer

This is rather complex issue. I think you should concentrate on simplifying your input data, rather then trying to come out with some convoluted TF code to post-fix your input data structures. Nevertheless, the TF code is:

variable "list_groups" {

  default = [
   {
       dev-api = {
           envs  = [
               "dev-eu-1",
               "dev-eu-2",
            ]
           hosts = [
               "dev-api-eu1",
               "dev-api-eu2",
            ]
        }
    },
   {
       dev-api = {
           envs  = [
               "dev-us-1",
               "dev-us-2",
            ]
           hosts = [
               "dev-api-us1",
               "dev-api-us2",
            ]
        }
    },
  ]

}


locals {
  api_names = distinct([for api in var.list_groups: keys(api)[0]])
}



output "test" {  
    value = {for key, val in {for api_name in local.api_names:
               api_name => {
                   envs = flatten([
                     for api in var.list_groups:
                       api[api_name].envs 
                   ])
                   hosts = flatten([
                     for api in var.list_groups:
                       api[api_name].hosts 
                   ])
                   }... 
              }: key => val[0]}
}

Output is:

test = {
  "dev-api" = {
    "envs" = [
      "dev-eu-1",
      "dev-eu-2",
      "dev-us-1",
      "dev-us-2",
    ]
    "hosts" = [
      "dev-api-eu1",
      "dev-api-eu2",
      "dev-api-us1",
      "dev-api-us2",
    ]
  }
}

Terraform merge list of maps

1 Answers