Ada adding items into an array

Question

`Hello I am working on a project where I have to sort through a text file and find the number of times a character occurs, I have everything just about done with it but I cant figure out how to add number of occurrences of each letter into an array so I can sort it. I believe once I can add the number of occurrences into an array as it goes through the Counters(I), I can get it to sort but I don't know how to add those items into an array can anyone help?

This is where I go through the txt file and print the results

This is how i declare everything and the sorting alg I am trying to use

 with Ada.Strings.Maps;
 with Ada.Text_IO; use Ada.text_io;
 with Ada.Integer_Text_IO; use Ada.Integer_Text_IO;
 with Ada.Float_Text_IO; use Ada.Float_Text_IO;  -- this if for float operations needed for percentages
                                                 --

procedure test is

   Counters: array (Character) of Integer := (others => 0); -- initialize all Counters to 0
   type Arr is array (Positive range <>) of Integer;
   C:        Character;
   Infile , OutFile : File_Type;
   Uppercount : Natural;
   Lowercount : Natural;
   Specialcount : Natural;
   --Occ : array :
   subtype  lower is Character range 'a'..'z'; -- lowercase letters
   subtype  upper is Character range 'A'..'Z'; -- uppercase letters
   --P : Arr := Counters;

   subtype Non_Negative_Float is Float range 0.0 .. Float'Last;
   Total : Non_Negative_Float;
   Total2 : Natural;
   --Counters : array_type;


   --sorting alg I am tring to use but cant get Counter(I) values to go into an array so I can sort it here
  procedure Sort (A : in out Arr) is
      Min  : Positive;
      Temp : Integer;
   begin
      for I in A'First..A'Last - 1 loop
         Min := I;
         for J in I + 1..A'Last loop
            if A (Min) > A (J) then
               Min := J;
            end if;
         end loop;
         if Min /= I then
            Temp    := A (I);
            A (I)   := A (Min);
            A (Min) := Temp;
         end if;
      end loop;
   end Sort;


begin
   Uppercount := 0;
   Lowercount := 0;
   Specialcount := 0;

   Open(InFile, In_File, ".\src\Exam2data.txt");
   Create(OutFile, Out_file, ".\src\Maginsky.txt");
   while not Ada.Text_IO.End_Of_File(InFile) loop
      Ada.Text_IO.Get(InFile, C);
      if C in lower then
      Lowercount := Lowercount + 1;
   elsif C in upper then
      Uppercount := Uppercount + 1;
   else
      Specialcount := Specialcount + 1;
   end if;
      Counters(C) := Counters(C) + 1;

     end loop;

 -- goes through the file and prints the letter and times is occures
   --needs to set Counters(I) values into an array as it goes through the for loop
   for I in Counters'Range loop
      if Counters(I) >= 0 then
         if I in lower or I in upper then
            -- I was not able to figure out how to put the Counters(I) into another array so it can get sorted
            -- I believe that if I can put the Counter(I) values into a new array i can sort that that array and get the
            -- correct decenting order as needed but I cant figure out how to put these values into an array for sorting
           --Sort(Counters(I));
            Ada.Text_IO.Put_Line("'" & I & "':" & Integer'Image(Counters(I)) & " Times");
            Ada.Text_IO.Put_Line(OutFile, "'" & I & "':" & Integer'Image(Counters(I)) & " Times");

         end if;
      end if;
   end loop;

user_6854407 · Answer

The following program collects the counts of the letters.

with Ada.Text_IO; use Ada.Text_Io;

procedure Main is
   subtype Upper is Character range 'A'..'Z';
   subtype Lower is Character range 'a'..'z';
   Upper_Count : array(Upper) of Natural := (Others => 0);
   Lower_Count : array(Lower) of Natural := (Others => 0);

   Filename    : String(1..1024);
   Length      : Natural;
   Input       : String(1..1024);
   The_File    : File_Type;
begin
   Put("Enter the name of the file to read: ");
   Get_Line(Item => Filename, Last => Length);
   Open(File => The_File,
        Mode => In_File,
        Name => Filename(1..Length));


   -- Read each character from the file and tally the letters

   while not End_Of_File(The_File) loop
      Get_Line(File => The_File, Item => Input, Last => Length);
      for I in 1..Length loop
         if Input(I) in Upper then
            Upper_Count(Input(I)) := Upper_Count(Input(I)) + 1;
         elsif Input(I) in Lower then
            Lower_Count(Input(I)) := Lower_Count(Input(I)) + 1;
         end if;
      end loop;
   end loop;

   close(The_File);

   -- Print the tally for each upper case letter
   for I in Upper_Count'Range loop
      Put_Line(I'Image & " " & Upper_Count(I)'Image);
   end loop;

   -- Print the tally for each lower case letter
   for I in Lower_Count'Range loop
      Put_Line(I'Image & " " & Lower_Count(I)'Image);
   end loop;

end Main;

You will need to consider how to sort the two arrays properly. I suggest you consider transferring the data acquired into an array of records such as:

type node is record
   C : Character;
   N : Natural;
end record;

type tally is array(1..52) of node;

You can then populate the tally array with each letter and its corresponding count, sort the array on the node.N field, and then print the array showing the character and its count.

EDIT: Show entire program including sorting the results

with Ada.Text_IO; use Ada.Text_IO;
with Ada.Containers.Generic_Array_Sort;

procedure count_and_sort is
   type node is record
      C : Character;
      N : Natural := 0;
   end record;

   function "<" (Left, Right : node) return Boolean is
   begin
      return Left.N < Right.N or else
        (Left.N = Right.N and Left.C < Right.C);
   end "<";

   subtype chars_index is Positive range 1 .. 52;
   type tally_type is array (chars_index range <>) of node;

   procedure Sort is new Ada.Containers.Generic_Array_Sort
     (Index_Type => chars_index, Element_Type => node,
      Array_Type => tally_type);
   subtype Upper is Character range 'A' .. 'Z';
   subtype Lower is Character range 'a' .. 'z';
   Upper_Count : array (Upper) of Natural := (others => 0);
   Lower_Count : array (Lower) of Natural := (others => 0);

   Filename : String (1 .. 1_024);
   Length   : Natural;
   Input    : String (1 .. 1_024);
   The_File : File_Type;
   Tally    : tally_type (chars_index'Range);
   Index    : Positive := 1;
begin
   Put ("Enter the name of the file to read: ");
   Get_Line (Item => Filename, Last => Length);
   Open (File => The_File, Mode => In_File, Name => Filename (1 .. Length));

   -- Read each character from the file and tally the letters

   while not End_Of_File (The_File) loop
      Get_Line (File => The_File, Item => Input, Last => Length);
      for I in 1 .. Length loop
         if Input (I) in Upper then
            Upper_Count (Input (I)) := Upper_Count (Input (I)) + 1;
         elsif Input (I) in Lower then
            Lower_Count (Input (I)) := Lower_Count (Input (I)) + 1;
         end if;
      end loop;
   end loop;

   Close (The_File);

   -- Populate the tally array

   for Item in Upper_Count'Range loop
      Tally (Index) := (Item, Upper_Count (Item));
      Index         := Index + 1;
   end loop;

   for Item in Lower_Count'Range loop
      Tally (Index) := (Item, Lower_Count (Item));
      Index         := Index + 1;
   end loop;

   -- sort Tally array
   Sort (Tally);

   -- Output sorted results
   for result of Tally loop
      Put_Line (result.C & " :" & result.N'Image);
   end loop;

end count_and_sort;

This example uses the predefined generic sort procedure provided in Ada.Containers.Generic_Array_Sort. You will see that I override the "<" function to compare the values the way I want. The array uses this overridden version implicitly. I don't know if you have studied the use of generic packages and subprograms. This example creates an instantiation of the generic array sort procedure to sort instances of my program's tally_type. I name that instance of the generic procedure "sort".

Ada adding items into an array

1 Answers