How to write global event handler procedure that makes controls visible/enabled

user_9044741 0
Viewed 118

I store controls 'visible' and 'enabled' property in DB table. Depending on user's role I make some controls not visible/enabled.

fields of db Table "Controls": id, role_id, form (varchar), comp_name(varchar), visible (boolean), enable (boolean)

query qControls: select * from controls where form=:form

calling of this procedure from OnShow of main form:

 application.CreateForm(TForm1, Form1);
 FORM := 'Form1';
 Form1.showModal;

Called procedure:

procedure RightsOnControls();
    var i:integer;
    
    begin
      fMain.qControls.Close;
      fMain.qControls.Params[0].AsString:= FORM; //FORM is global variable:  FORM:='Form1' 
      fMain.qControls.Open;
      if fMain.qControls.RecordCount>0 then begin
        while not fMain.Controls.Eof do begin
          for I := 0 to form1.ControlCount - 1 do
            if uppercase(form1.Controls[i].Name)= uppercase(fMain.qControlsComp_name.AsString) then
               begin
                form1.Controls[i].Visible:=fmain.qControlsVisible.AsBoolean;
                form1.Controls[i].Enabled:=fmain.qControlsEnable.AsBoolean;
               end;
        fMain.qControls.next;
        end;
      end;
    end;

My questions are:

  1. how make procedure as general event handler,not for only Form1?
  2. It finds only controls located on form, not controls located on the panel/Page control (tabsheet). How change it?
delphi
1 Answers

Call this procedure with the form to handle (f.i. form1) and the query (fMain.qControls):

procedure RightsOnControls(AForm: TForm; AQuery: TFDQuery);

  function FindChildControl(Parent: TWinControl; const ControlName: string): TControl;
  var
    I: Integer;
  begin
    for I := 0 to Parent.ControlCount - 1 do begin
      Result := Parent.Controls[I];
      if SameText(Result.Name, ControlName) then Exit;

      if Result is TWinControl then begin
        Result := FindChildControl(TWinControl(Result), ControlName);
        if Result <> nil then Exit;
      end;
    end;
    Result := nil;
  end;

var
  ctl: TControl;
begin
  AQuery.Close;
  AQuery.Params[0].AsString := AForm.Name;
  AQuery.Open;
  while not AQuery.Eof do begin
    ctl := FindChildControl(AForm, AQuery.FieldByName('Comp_name').AsString);
    if ctl <> nil then begin
      ctl.Visible := AQuery.FieldByName('Visible').AsBoolean;
      ctl.Enabled := AQuery.FieldByName('Enable').AsBoolean;
    end;
    AQuery.next;
  end;
end;

In case you don't use FireDAC, change the query type to whatever is appropriate.

user_268330
Related