Search column and store inside variable using grep or awk

You may use this generic solution using awk:

cat srch.awk
BEGIN{ FS = "[[:blank:]]*[|]" }
{
   for (i=1; i<=NF; ++i) {
      if (match($i, /^[_[:alnum:]]+: /) && substr($i, 1, RLENGTH-2) == fld) {
          print ( substr($i, RLENGTH+1) )
          next
      }
   }
}

Then use it as:

awk -v fld='isp' -f srch.awk file.txt

OVH Hosting Inc.
Teredo RFC4380
Teredo RFC4380
Teredo RFC4380
Teredo RFC4380
Teredo RFC4380
Teredo RFC4380

Or else:

awk -v fld='usage_type' -f srch.awk file.txt

Data Center/Web Hosting/Transit
Reserved
Search Engine Spider
Hacking
Gaming
IPS
Commercial

How about using sed to isolate the field (using "|" as a delimiter):

isp=$(sed -E 's/^.*\|isp: ([^|]*)( \|.*)?$/\1/' file.txt)

One possible problem with this is that if a line doesn't match it'll leave the entire line in, rather than giving a blank result. Depending on the setup, you could use sed's -n option and the p modifier on the replacement:

sed -nE 's/^.*\|isp: ([^|]*)( \|.*)?$/\1/p'

... which will print nothing if there's no match. But then if you process the entire file, non-matching lines will vanish (rather than becoming blank). Depending on how you're using it, this might need fixing.

Alternately, if you like awk and the isp will always be the third "|"-delimited field (fourth if you count the "|" at the beginning):

awk -F'|' '{sub("^isp: ", "", $4); print $4}'

Could you please try following, written and tested with shown samples in GNU awk. We have an awk variable named search just give your string in it and it will look for it in lines and print the matched part accordingly.

awk -v search="isp" '
match($0,search ":[^|]*"){
  val=substr($0,RSTART,RLENGTH)
  sub(/[^:]*: +/,"",val)
  print val
  val=""
}' Input_file

Explanation: Adding detailed explanation for above.

awk -v search="isp" '             ##Starting awk program and setting variable search isp here.
match($0,search ":[^|]*"){        ##Using match function to look for regexp(from search variable value colon till pipe match everything).
  val=substr($0,RSTART,RLENGTH)   ##Creating val which has sub string of matched regex.
  sub(/[^:]*: +/,"",val)          ##Substituting everything till colon with NULL in val.
  print val                       ##Printing variable vale here.
  val=""                          ##Nullify val here.
}' Input_file                     ##Mentioning Input_file name here.

2nd solution: Adding more generic solution, where if anyone wants to search multiple ids in a single awk we could do it. Just provide all strings which you need to search inside variable search with ,(comma) delimiter and we will get all those matches.

awk -v search="isp,usage_type" '
BEGIN{
  num=split(search,arr,",")
  for(i=1;i<=num;i++){
    valCheck[arr[i]]
  }
}
{
  for(key in valCheck){
    match($0,key ":[^|]*")
    val=substr($0,RSTART,RLENGTH)
    sub(/[^:]*: +/,"",val)
    valPrint[key]=(valPrint[key]?valPrint[key] ORS:"")val
    val=""
  }
}
END{
  for(key in valPrint){
    print "Printing values for " key "....." ORS valPrint[key]
  }
}' Input_file

Simple Perl

$ perl -lne ' /isp:\s*([^|]+)/ and print $1 ' azimah.txt
OVH Hosting Inc.
Teredo RFC4380
Teredo RFC4380
Teredo RFC4380
Teredo RFC4380
Teredo RFC4380
Teredo RFC4380
$