Best way to go to any line number we want in Perl

This question very much seems as though an XY-problem. Or homework. The logic of counting "you"s connected to certain key words seems arbitrary. The "you"s following "Good", for example, will contain all the "you"s in the other words combined.

As I assume this is some sort of learning exercise, I will comment your code, then come with a suggested solution.

open(IN1, "<$log1_file" ) or die "Could not open file $log1_file: $!";

Always use the three argument open with explicit open mode to avoid code injection. Use a lexical file handle (my $fh) instead of a global bareword (IN1). It should look like this:

open my $fh, "<", $log1_file or die "Could not open '$log1_file': $!";

This split is unnecessary

my @fields = split' ',$line;

Since you only have one word on each line, all this does is remove the newline on the end (because splitting on ' ' is a special case). If you want to remove the newline, you should use chomp, like this: chomp($line)

Using seek and tell to navigate around your file is likely the wrong solution. While you can make it work, there are better solutions.

Using three almost identical subroutines to do the exact same thing (almost) is bad practice, IMO. Using global variables inside the subroutines is also not a good thing. What you should seek is encapsulation: Feed the information you need to the subroutine, and return the values you want afterwards. For example:

my @file = <$fh>     # slurp the file into an array
....
if (/^Good$/) {
    $good_count += you_check($line_number);
} elsif (/^make$/) {
    $make_count += you_check($line_number);
} ....etc

sub you_check {
    my $line_number = shift;
    my $count = 0;
    for my $line ($file[$line_number] .. $file[$#file]) {
        $count++ if $line =~ /^you$/;
    }
    return $count;
}

Assuming we keep @file unchanged, the you_check() function can be used without worrying that using it will alter something else.

With that said, if I was to solve this task, I would use a hash. It will allow you to dynamically determine the keyword, and add new keywords without having to add a lot of new code.

use strict;
use warnings;
use Data::Dumper;

my %count;
my $key;
while (<>) {
    if (/(Good|make|love)/) {
        $key = $1;
    }
    if (/you/) {
        $count{$key}++ if $key;
    }
}
print Dumper \%count;

Use it like this on the command line:

$ count.pl log.log

The output when used with your sample data is:

$VAR1 = {
          'love' => 2,
          'Good' => 2,
          'make' => 2
        };

If you still wanted to maintain the rule that the first word count contains all other words, you can keep track of which word comes first and then just add the counts afterwards. Using a hash for this count is scalable for as many words as you like to keep track of.

Files are streams of bytes. They don't understand lines at all. The line-end character is just another character in the stream.

So when the documentation for seek() talks about a "FILEHANDLE's position", it means the number of bytes through the file, not the number of lines. So seeking to a line number is never going to have the result that you want.

Instead, you should use the tell() function to find out which position you are at in the file and then use that value as the parameter that you send to seek().

It would work something like this:

# Lexical filehandle and three-arg open()
open my $in_fh, '<', $log1_file or die ...;

my $pos = tell $in_fh;

while (my $line = <$in_fh>) {

  # Do various stuff.

  # If you want to go back to the start of the line.
  seek $in_fh, $pos, 0;

  # Get the pos at the end of the current line
  $pos = tell $in_fh;
}

Update: If you want to be able to go to any line in a file, then one approach might be to read through the file once and call tell() at the start of every line. You can then store those values in an array which you can use to get to the start of any line.