How to emit a token in ANTLR4?

user_187141 0
Viewed 358

This is my grammar.g4:

FOO: 'x';
BAR: 'y'
  { /* here! */ };

I want tokens BAR and FOO to be emitted when the input contains y. What should I write in the here! part? Please, don't suggest to rewrite the grammar, this is just a test sample, my real case is much more complex.

antlr4 antlr java
1 Answers

Here's a quick demo:

grammar T;

@lexer::members {
  private java.util.LinkedList<Token> tokens = new java.util.LinkedList<>();

  @Override
  public Token nextToken() {
    return tokens.isEmpty() ? super.nextToken() : tokens.poll();
  }
}

parse
 : foo bar foo EOF
 ;

foo : FOO;
bar : BAR;

FOO : 'x';
BAR : 'y' {this.tokens.offer(new CommonToken(TLexer.FOO, "x"));};

SPACES : [ \t\r\n] -> skip;

Test with:

TLexer lexer = new TLexer(CharStreams.fromString("x y"));
TParser parser = new TParser(new CommonTokenStream(lexer));

System.out.println(parser.parse().toStringTree(parser));

which will print:

(parse (foo x) (bar y) (foo x) <EOF>)
user_504760
Related