Read CSV to parse data and store it in Hash

Changes made to the script posted was to remove the header line so that it does not form part of the result and added a for loop to set the reset of the data.

Test Data Used:

id,Time,Name,Cell,,,,,
1,7/2/2020 11:00,Name1,NCell1,PMR,1001,ISD,ISDVAL1
2,7/3/2020 13:10,Name2,NCell3,PMR,1002,PCO,PCOVAL2,MKR,MKRVAL2

Updated Script: (This was the first version suggest using the improved version in the edit)

#!/usr/bin/perl

use strict;
use warnings;

use Text::CSV;
use Data::Dumper;

my %hash;

my $csv = Text::CSV->new ({ binary => 1, auto_diag => 1 });
open my $fh, "<:encoding(utf8)", "input_file.csv" or die "input_file.csv: $!";
my $headers = $csv->getline ($fh);
while (my $row = $csv->getline ($fh)) {
    $hash{$row->[0]}{Time} = $row->[1];
    $hash{$row->[0]}{Name} = $row->[2];
    $hash{$row->[0]}{Cell} = $row->[3];
    for (my $i = 4; $i < scalar (@{$row}); $i += 2) {
        $hash{$row->[0]}{$row->[$i]} = $row->[$i + 1];
    }
}
close $fh;

print Dumper(\%hash);

Output:

$VAR1 = {
          '2' => {
                   'MKR' => 'MKRVAL2',
                   'Name' => 'Name2',
                   'PCO' => 'PCOVAL2',
                   'Cell' => 'NCell3',
                   'Time' => '7/3/2020 13:10',
                   'PMR' => '1002'
                 },
          '1' => {
                   'Name' => 'Name1',
                   'ISD' => 'ISDVAL1',
                   'Cell' => 'NCell1',
                   'Time' => '7/2/2020 11:00',
                   'PMR' => '1001'
                 }
        };

Edit:

Thanks to comment from @choroba here is an improved version of the script setting the hash with all the additional row values first and then adding the first values Time Name Cell using the header line read from the file.

#!/usr/bin/perl

use strict;
use warnings;

use Text::CSV;
use Data::Dumper;

my %hash;

my $csv = Text::CSV->new ({ binary => 1, auto_diag => 1 });
open my $fh, "<:encoding(utf8)", "input_file.csv" or die "input_file.csv: $!";
my $headers = $csv->getline ($fh);
while (my $row = $csv->getline ($fh)) {
    $hash{$row->[0]} = { @$row[4 .. $#$row] };
    @{$hash{$row->[0]}}{@$headers[1, 2, 3]} = @$row[1, 2, 3];
}
close $fh;

print Dumper(\%hash);

There are some Text::CSV features that you can use to make this a bit simpler. There's a lot of readability to gain by removing density in the loop.

First, you can set the column names for missing header values. I don't know what those columns represent so I've called them K1, V1, and so on. You can substitute better names for them. How I do that isn't as important is that I do that. I'm using v5.26 because I'm using postfix dereferencing:

use v5.26;
my $headers = $csv->getline($fh);

my @kv_range = 1 .. 4;
$headers->@[4..11] = map { ("K$_", "V$_") } @kv_range;
$csv->column_names( $headers );

If I knew the names, I could use those instead of numbers. I merely change the stuff in @kv_range:

my @kv_range = qw(machine test regression ice_cream);

And, when the data file changes, I handle all of that here. When it's outside the loop, there's much less to miss.

Now that I have all columns named, I use getline_hr to get back a hash reference of the line. The keys are the column names I just set. This does a lot of the work for you already. You have to handle the pairs at the end, but that's going to be easy too:

my %Grand;
while( my $row = $csv->getline_hr($fh) ) {
    foreach ( @kv_range ) {
        no warnings 'uninitialized';
        $row->{ delete $row->{"K$_"} } = delete $row->{"V$_"};
        }
    $Grand{ $row->{id} } = $row;
    delete $row->@{ 'id', '' };
    }

Now to handle the pairs at the end: I want to take the value in the column K1 and make it a key, then take the value in V1 and make that the value. At the same time, I need to remove those K1 and V1 columns. delete has the nice behavior in that it returns the value for the key you deleted. This way doesn't require any sort of pointer math or knowledge about positions. Those things might change and I've handled all of that before I got this far:

        $row->{ delete $row->{"K$_"} } = delete $row->{"V$_"};

You could also do this in a couple steps if that statement is too much for you:

        my( $key, $value ) = delete $row->@{ "K$_", "V$_" };
        $row->{$key} = $value;

I'd leave the id column in there, but if you don't want it, get rid of it. Also, that step with the deletes might have made some empty string keys for the cells that had no values. Instead of guarding against that and making the foreach more complicated, I let it happen and get rid of it at the end:

    delete $row->@{ 'id', '' };

Altogether, it looks like this. It's doing the same thing as Piet Bosch's answer, but I've pushed a lot of the complexity back into the module as well as doing a little pre-loop work:

use v5.26;
use strict;
use warnings;

use Data::Dumper;
use Text::CSV;

my $csv = Text::CSV->new({
    binary    => 1,
    auto_diag => 1
    });

open my $fh, "<:encoding(utf8)", "input_file.csv"
    or die "input_file.csv: $!";

my $headers = $csv->getline($fh);

my @kv_range = 1 .. 4;
$headers->@[4..11] = map { ("K$_", "V$_") } @kv_range;
$csv->column_names( $headers );

my %Grand;
while( my $row = $csv->getline_hr($fh) ) {
    foreach ( @kv_range ) {
        no warnings 'uninitialized';
        $row->{ delete $row->{"K$_"} } = delete $row->{"V$_"};
        }
    $Grand{ $row->{id} } = $row;
    delete $row->@{ 'id', '' };
    }

say Dumper( \%Grand );

And the output looks like this:

$VAR1 = {
          '2' => {
                   'PMR' => '1002',
                   'PCO' => 'PCOVAL2',
                   'MKR' => 'MKRVAL2',
                   'Name' => 'Name2',
                   'Time' => '7/3/2020 13:10',
                   'Cell' => 'NCell3'
                 },
          '1' => {
                   'Cell' => 'NCell1',
                   'Time' => '7/2/2020 11:00',
                   'ISD' => 'ISDVAL1',
                   'PMR' => '1001',
                   'Name' => 'Name1'
                 }
        };