Grails databinding - How to exclude child property

blacklist parameter supports only direct object properties

you can use DataBindingListener

import grails.databinding.events.DataBindingListenerAdapter

class BlackListener extends DataBindingListenerAdapter{
    List<String> list
    //returns false if you want to exclude property from binding
    public Boolean beforeBinding(Object obj, String propertyName, Object value, Object errors) {
        return !list.contains("${obj?.class.name}.${propertyName}".toString())
    }
}

...

List blackList = ["Car.carPropertyToExclude", "Details.detailPropertyToExclude"]
grailsWebDataBinder.bind(car, new SimpleMapDataBindingSource(params), 
                new BlackListener(list:blackList) )

UPD:

Unfortunately the method above does not work with Collection binding.

The problem that SimpleDataBinder.setPropertyValue(...) method loses listener when processing a list.

Not sure if following workaround is good (potentially context initialization required)

but it's possible to register converter for each black list:

import grails.databinding.SimpleDataBinder
import grails.databinding.SimpleMapDataBindingSource
import grails.databinding.converters.ValueConverter

SimpleDataBinder setBlackList(SimpleDataBinder binder, Map<Class,List<String>> blackLists) {
    blackLists.each { Class clazz, List<String> blackList ->
        def vc = new ValueConverter(){
            boolean canConvert(Object value){
                return value instanceof Map
            }
            Object convert(Object value){
                def obj = clazz.newInstance()
                binder.bind( obj, new SimpleMapDataBindingSource(value), [], blackList )
                return obj
            }
            Class<?> getTargetType(){ clazz }
        }
        binder.registerConverter(vc)
    }
    return binder
}

...

Map blackLists = [
    (Car.class)    : ["carPropertyToExclude"],
    (Detail.class) : ["detailPropertyToExclude"]
]

setBlackList(grailsWebDataBinder,blackLists)

...

grailsWebDataBinder.bind(car, new SimpleMapDataBindingSource(params), null, 
         blackLists[car.getClass()] )

PS: as alternative possible to set grailsWebDataBinder.conversionService...

In a controller you can exclude props from binding by:

def someAction(){
  Car car = new Car()
  bindData car, params, [exclude: ['carPropertyToExclude', 'details']]

  car.details = params.list('details').collect{
    bindData new Detail(), [exclude: ['detailPropertyToExclude']]
  }
}

You might also want to use the command-objects to represent your form-data.

I have found one solution based on daggett answer. Maybe in greater versions, the bug is fixed or will be fixed. The bug is that when we give the listener as a parameter of bind method for child domains the listener isn't triggered but when we set it as class level listener works. Grails version 3.2.11.

I have created the BlackListener like this:

public class BlackListListener extends DataBindingListenerAdapter {
private final Map<Class<?>, Collection<String>> blackList;

public BlackListListener(Map<Class<?>, Collection<String>> blackList) {
    this.blackList = blackList;
}

public Boolean beforeBinding(Object obj, String propertyName, Object value, Object errors) {

        Boolean result = Boolean.TRUE;

        Collection<String> list = blackList.get(obj.getClass());

        if (CollectionUtils.isNotEmpty(list)) {
            result = !list.contains(propertyName);
        }

        return result;
    }
}

Then I make my own grailsWebDatabinder bean as prototype:

<bean id="webDataBinder" class="grails.web.databinding.GrailsWebDataBinder" c:_0-ref="grailsApplication"
      scope="prototype"/>
<bean id="carBinder" class="CarDataBinder" c:_0-ref="webDataBinder"/>

and then when I want to use data binder I inject the webDataBinder and init listener:

public CarDataBinder(GrailsWebDataBinder grailsWebDataBinder) {
    this.grailsWebDataBinder = grailsWebDataBinder;

    DataBindingListener blackListListener = new BlackListListener(
        ImmutableMap.of(
                    Car.class, ImmutableSet.of("carPropertyToExclude"),
                    Detail.class, ImmutableSet.of("detailPropertyToExclude")
            )
        );

    grailsWebDataBinder.setDataBindingListeners(blackListListener);
}

and then:

void bindData(Car car, Map<?, ?> params) {
    grailsWebDataBinder.bind(car, new SimpleMapDataBindingSource(params));
}

If there are better ways you can post.