I used the code bellow for executing terminal-commands in an Excel-VBA. The function ExecCmdOld is called with the command and its parameters (cmdline$) and the boolean-variable if there is a progressbar displayed. The string returned is the result of the command. With Office 32-bit that code worked fine but after the migration to Office 64-bit there is always an error with CreatePipe (showed in the MsgBox) which means "Illegal access to a memory area". Implementing the PtrSafe-tags did not work. So what did I forget? Thanks for your help!
If there is any other way for executing a console command with hidden console window, getting result without a temporary text file and a possibility to show the user that there is something in progress (eg. the progress bar) I would also be very thankful.
Option Explicit
Private Const FORMAT_MESSAGE_FROM_SYSTEM = &H1000
Private Declare PtrSafe Function CopyFile Lib "kernel32" Alias "CopyFileA" (ByVal lpExistingFileName As String, ByVal lpNewFileName As String, ByVal bFailIfExists As Long) As Long
Private Declare PtrSafe Function FormatMessage Lib "kernel32" Alias "FormatMessageA" (ByVal dwFlags As Long, lpSource As Any, ByVal dwMessageId As Long, ByVal dwLanguageId As Long, ByVal lpBuffer As String, ByVal nSize As Long, Arguments As Long) As Long
Private Declare PtrSafe Function CreatePipe Lib "kernel32" (phReadPipe _
As LongPtr, phWritePipe As LongPtr, lpPipeAttributes As Any, _
ByVal nSize As Long) As Long
Private Declare PtrSafe Function ReadFile Lib "kernel32" (ByVal hFile _
As LongPtr, ByVal lpBuffer As String, ByVal _
nNumberOfBytesToRead As Long, lpNumberOfBytesRead As _
Long, ByVal lpOverlapped As Any) As Long
Private Declare PtrSafe Function CreateProcessA Lib "kernel32" (ByVal _
lpApplicationName As Long, ByVal lpCommandLine As _
String, lpProcessAttributes As Any, lpThreadAttributes _
As Any, ByVal bInheritHandles As Long, ByVal _
dwCreationFlags As Long, ByVal lpEnvironment As Long, _
ByVal lpCurrentDirectory As Long, lpStartupInfo As Any, _
lpProcessInformation As Any) As Long
Private Declare PtrSafe Function CloseHandle Lib "kernel32" (ByVal _
hObject As LongPtr) As Long
Private Declare PtrSafe Function PeekNamedPipe Lib "kernel32" (ByVal _
hNamedPipe As LongPtr, lpBuffer As Any, ByVal nBufferSize _
As Long, lpBytesRead As Long, lpTotalBytesAvail As Long, _
lpBytesLeftThisMessage As Long) As Long
Private Declare PtrSafe Function WaitForSingleObject Lib "kernel32" ( _
ByVal hHandle As Long, ByVal dwMilliseconds As Long) As Long
Private Type SECURITY_ATTRIBUTES
nLength As Long
lpSecurityDescriptor As Long
bInheritHandle As Long
End Type
Private Type STARTUPINFO
cb As Long
lpReserved As Long
lpDesktop As Long
lpTitle As Long
dwX As Long
dwY As Long
dwXSize As Long
dwYSize As Long
dwXCountChars As Long
dwYCountChars As Long
dwFillAttribute As Long
dwFlags As Long
wShowWindow As Integer
cbReserved2 As Integer
lpReserved2 As Long
hStdInput As Long
hStdOutput As LongPtr
hStdError As Long
End Type
Private Type PROCESS_INFORMATION
hProcess As Long
hThread As Long
dwProcessId As Long
dwThreadId As Long
End Type
Private Const STARTF_USESTDHANDLES = &H100&
Private Const NORMAL_PRIORITY_CLASS = &H20&
Private Const STARTF_USESHOWWINDOW As Long = &H1&
Private Function ExecCmdOld(cmdline$, balken As Boolean) As String
Dim proc As PROCESS_INFORMATION
Dim start As STARTUPINFO
Dim sa As SECURITY_ATTRIBUTES
Dim hReadPipe As LongPtr, hWritePipe As LongPtr
Dim L As Long, result As Long, bSuccess As Long
Dim Buffer As String
Dim k As Long
Dim retText As String
sa.nLength = Len(sa)
sa.bInheritHandle = 1&
sa.lpSecurityDescriptor = 0&
result = CreatePipe(hReadPipe, hWritePipe, sa, 0)
Dim strMessage As String
strMessage = Space$(512)
Dim lngStatus As Long
If result = 0 Then
lngStatus = FormatMessage(FORMAT_MESSAGE_FROM_SYSTEM, ByVal 0, Err.LastDllError, 0, strMessage, Len(strMessage), 0)
MsgBox strMessage
MsgBox "CreatePipe failed Error!"
Exit Function
End If
With start
.cb = Len(start)
.dwFlags = STARTF_USESTDHANDLES Or STARTF_USESHOWWINDOW
.hStdOutput = hWritePipe
.wShowWindow = vbHide ' *** von rkhb: Konsolenfenster nicht zeigen
End With
result = CreateProcessA(0&, cmdline$, sa, sa, 1&, _
NORMAL_PRIORITY_CLASS, 0&, 0&, start, proc)
If result <> 0 Then
'*** Anfang der Verbesserung Achim Neubauer***
Dim lPeekData As Long
k = 0
Do
Call PeekNamedPipe(hReadPipe, ByVal 0&, 0&, ByVal 0&, _
lPeekData, ByVal 0&)
If lPeekData > 0 Then
Buffer = Space$(lPeekData)
bSuccess = ReadFile(hReadPipe, Buffer, Len(Buffer), L, 0&)
If bSuccess = 1 Then
retText = retText & Left(Buffer, L)
Else
MsgBox "ReadFile failed!"
End If
Else
bSuccess = WaitForSingleObject(proc.hProcess, 0&)
If bSuccess = 0 Then
Exit Do
End If
End If
If balken Then
If k = 100000 Then
k = 0
End If
k = k + 1
UserFormBalken.ProgressBar1 = k / 1000
End If
DoEvents
Loop
'*** Ende der Verbesserung Achim Neubauer ***
Else
MsgBox "Error while starting process!"
End If
Call CloseHandle(proc.hProcess)
Call CloseHandle(proc.hThread)
Call CloseHandle(hReadPipe)
Call CloseHandle(hWritePipe)
ExecCmdOld = retText
End Function ```