Using findmin() in data from array composed of mutable struct elements - Julia

user_13155909 0
Viewed 299

Suppose I have the following struct:

mutable struct Car
    load
    locale
    availability
    odometer
end

And I have created an array: 

fleet = Vector{Car}(undef, num_cars)

for i in 1:num_cars
   a, b, c, d = rand(4)
   fleet[i] = Car(a, b, c, d)
end

How can I find the smallest (with findmin or similar) or biggest (with?) value from, for example, the odometer of all the cars in my array?

Basically, I want to be able to use conditional statements with struct arrays, e.g.: For every element in my struct array, get the ones that a data satisfy a condition and, from those, get the minimum value of another data.

Thanks!

julia mutable methods struct arrays
2 Answers

Finding the minimum value is pretty straightforward, using the minimum function, with a mapping argument:

julia> minimum(x->x.odometer, fleet)
0.08468003971220694

If you also want the index of the minimum, you can use the findmin function. Unfortunately, this does not, for some reason, support a function argument, so you have to create a temporary array, and apply findmin to that:

julia> findmin(getfield.(fleet, :odometer))
(0.08468003971220694, 1)

You can also use getproperty instead of getfield, they do the same thing for your struct, I'm not certain which is preferable. Probably, the most idiomatic solution would be to define accessor functions instead of using the field values directly. For example:

odometer(car::Car) = car.odometer
minimum(odometer, fleet)
findmin(odometer.(fleet))

For maximum values, use maximum and findmax.

user_27498650

Julia is about performance.

You should avoid using untyped structs hence your type definition should be:

mutable struct Car
    load::Float64
    locale::Float64
    availability::Float64
    odometer::Float64
end

The code for creating Vector can be shorter:

cars = [Car(rand(4)...) for _ in 1:5]

The most efficient way to find the index of the minimum element is:

julia> Base.isless(c1::Car,c2::Car) = c1.odometer < c2.odometer

julia> findmin(cs)
(Car(0.7623514815463603, 0.7523019237133661, 0.37422766075278413, 0.49830949323733464), 3)
user_99577100
Related