Using has_many - belongs_to association when using UUID (String)

user_11608409 0
Viewed 981

I'm trying to associate two models (user & country) where:

· A country has_many users.

· A user belongs_to one country.

Also, I use UUIDs as Primary Key for the two models, so I don't have an :id type to relate them and only have strings to do it. The countries are static but I will create a lot of users.

How should I relate this two models and which parameters should I write in the two functions in the schemas (has_many & belongs_to)? And which function should I call to relate them: cast_assoc, build_assoc or put_assoc?

Thanks!!

  @primary_key {:uuid, :string, []}
  @derive {Phoenix.Param, key: :uuid}
  schema "countries" do
    field :country_name, :string

    has_many :users, UserManagement.User, foreign_key: :country_id
  end

  @primary_key {:uuid, :string, []}
  @derive {Phoenix.Param, key: :uuid}
  schema "users" do
    field :nickname, :string
    field :password, :string, virtual: true

    belongs_to :country, UserManagement.Country, references: :uuid

    timestamps()
  end
phoenix-framework elixir belongs-to has-many uuid
2 Answers

You can pass the :type option in belongs_to:

belongs_to :country, UserManagement.Country, references: :uuid, type: :string

And all of the association functions and helpers should work. You can find all available options here: https://hexdocs.pm/ecto/Ecto.Schema.html#belongs_to/3

If you want all of your schemas to use UUID, you can encapsulate the setup in a custom module like this:

defmodule MyApp.Schema do
  defmacro __using__(_) do
    quote do
      use Ecto.Schema
      @primary_key {:uuid, :string, []}
      @foreign_key_type :string
      @derive {Phoenix.Param, key: :uuid}
    end
  end
end

And now instead of use Ecto.Schema you do use MyApp.Schema.

user_5882670

If you're using the accepted answer from Jose Valim and you're also setting autogenerate: true on your custom schema @primary_key, you'll want the MyApp.Schema module to use type Ecto.UUID.

This would look like:

@primary_key {:uuid, Ecto.UUID, autogenerate: true}

If not, schemas using this base schema will throw (ArgumentError) field :uuid does not support :autogenerate because it uses a primitive type :string.

user_10758570
Related