Accessing object in iframe using VBA

Question

To the point:

I have successfully used VBA to do the following:

Login to a website using getElementsByName
Select parameters for the report that will be generated (using getelementsby...)
generating the report after selecting parameters which renders the resulting dataset into an iframe on the same page

Important to note - The website is client-side

The above was the simple part, the difficult part is as below:

clicking on a gif image within the iframe that exports the dataset to a csv

I have tried the following:

Dim idoc As HTMLDocument
Dim iframe As HTMLFrameElement
Dim iframe2 As HTMLDocument

Set idoc = objIE.document
Set iframe = idoc.all("iframename")
Set iframe2 = iframe.contentDocument

    Do Until InStr(1, objIE.document.all("iframename").contentDocument.innerHTML, "img.gif", vbTextCompare) = 0
        DoEvents
    Loop

To give some context to the logic above -

I accessed the main frame
i accessed the iframe by its name element
i accessed the content within the iframe
I attempted to find the gif image that needs to be clicked to export to csv

It is at this line that it trips up saying "Object doesn't support this property or method"

Also tried accessing the iframe gif by the a element and href attribute but this totally failed. I also tried grabbing the image from its source URL but all this does it take me to the page the image is from.

note: the iframe does not have an ID and strangely the gif image does not have an "onclick" element/event

Final consideration - attempted scraping the iframe using R

accessing the HTML node of the iframe was simple, however trying to access the attributes of the iframe and subsequently the nodes of the table proved unsuccessful. All it returned was "Character(0)"

library(rvest)
library(magrittr)

Blah <-read_html("web address redacted") %>%
  html_nodes("#iframe")%>%
  html_nodes("#img")%>%
  html_attr("#src")%>%
  #read_html()%>%
  head()
Blah

As soon as a i include read_html the following error returns on the script:

Error in if (grepl("<|>", x)) { : argument is of length zero

I suspect this is referring to the Character(0)

Appreciate any guidance here!

Many Thanks,

HTML

x -

user_6241235 · Answer

I thought I would expand on the answer already given.

In the case of Internet Explorer you may have one of two common situations to handle regarding iframes.

src of iframe is subject to same origin policy restrictions:

The iframe src has a different origin to the landing page in which case, due to same origin policy, attempts to access it will yield access denied.

Resolution:

Consider using selenium basic to automate a different browser such as Chrome where CORS is allowed/you can switch to the iframe and continue working with the iframe document

Example:

Option Explicit
'download selenium https://github.com/florentbr/SeleniumBasic/releases/tag/v2.0.9.0
'Ensure latest applicable driver e.g. ChromeDriver.exe in Selenium folder
'VBE > Tools > References > Add reference to selenium type library
Public Sub Example()
    Dim d As WebDriver
    Const URL As String = "https://www.rosterresource.com/mlb-roster-grid/"
    Set d = New ChromeDriver
    With d
        .Start "Chrome"
        .get URL
        .SwitchToFrame .FindElementByCss("iframe") '< pass the iframe element as the identifier argument
        ' .SwitchToDefaultContent ''to go back to parent document.
        Stop '<== delete me later
        .Quit
    End With
End Sub

src of iframe is not subject to same origin policy restrictions:

Resolution:

The methods as detailed in answer already given. Additionally, you can extract the src of the iframe and .Navigate2 that to access

.Navigate2 .document.querySelector("iframe").src

If you only want to work with the contents of the iframe then simply do your initial .Navigate2 the iframe src and don't even visit the initial landing page

Example:

Option Explicit
Public Sub NavigateUsingSrcOfIframe()
    Dim IE As New InternetExplorer
    With IE
        .Visible = True
        .Navigate2 "http://www.bursamalaysia.com/market/listed-companies/company-announcements/5978065"

        While .Busy Or .readyState < 4: DoEvents: Wend
        
        .Navigate2 .document.querySelector("iframe").src
        
        While .Busy Or .readyState < 4: DoEvents: Wend

        Stop '<== delete me later
        .Quit
    End With
End Sub

iframe in ShadowRoot

An unlikely case might be an iframe in shadowroot. You should really have one or the other and not one within the other.

Resolution:

In that case you need an additional accessor of

Element.shadowRoot.querySelector("iframe").contentDocument

where Element is your parent element with shadowRoot attached. This method will only work if the shadowRoot mode is set to Open.

Side note:

A nice selenium based example, using ExecuteScript to return shadowRoot is given here: How Do I Access Elements in the Shadow DOM using Selenium in VBA?

user_14944469 · Answer

Adding to the answers given:

If you're ok with using a DLL and rewrite your code, you can run Microsoft's Edge browser (a Chrome-based browser) with VBA. With that you can do almost anything you want. Note however, that access to the DOM is performed by javascript, not by an object like Dim IE As New InternetExplorer. Look at the VBA sample and you'll get the grasp.

https://github.com/peakpeak-github/libEdge

Sidenote: Samples for C# and C++ are also included.

Accessing object in iframe using VBA

3 Answers