How to find the greatest value per ID in Microsoft Excel Power Query?

To keep the duplicates at the end, you have to fiddle around with the M. Here you go.

let
    Source = Table.FromRows(Json.Document(Binary.Decompress(Binary.FromText("i45WMjE2UFDSUTI0MlCK1YFzzaFcU1RZKNcMyjVDlcXONcPCjQUA", BinaryEncoding.Base64), Compression.Deflate)), let _t = ((type nullable text) meta [Serialized.Text = true]) in type table [#"JOB_ID " = _t, DAY_ID = _t]),
    #"Changed Type" = Table.TransformColumnTypes(Source,{{"JOB_ID ", Int64.Type}, {"DAY_ID", Int64.Type}}),
    #"Grouped Rows" = Table.Group(#"Changed Type", {"JOB_ID "}, {{"All", each 

    let a = List.Max(_[DAY_ID]),
    b =  List.Select(_[DAY_ID], each _ =   a)
    in b

    , type list}}),
    #"Expanded All" = Table.ExpandListColumn(#"Grouped Rows", "All")
in
    #"Expanded All"

• Group by JOB_ID
• Aggregate by filtering each subtable by the maximum DAY_ID

let

//Change next line to reflect actual data source
    Source = Excel.CurrentWorkbook(){[Name="Table20"]}[Content],
    #"Changed Type" = Table.TransformColumnTypes(Source,{{"JOB_ID", Int64.Type}, {"DAY_ID", Int64.Type}}),

//Group by JOB_ID
//  Filter each subtable by maximum DAY_ID
    #"Grouped Rows" = Table.Group(#"Changed Type", 
        {"JOB_ID"}, {
            {"DAY_ID", (t)=>Table.SelectRows(t, each [DAY_ID]=List.Max(t[DAY_ID])), 
                    type table [JOB_ID=Int64.Type, DAY_ID=Int64.Type]}}),
    #"Removed Columns" = Table.RemoveColumns(#"Grouped Rows",{"JOB_ID"}),
    
    #"Expanded DAY_ID" = Table.ExpandTableColumn(#"Removed Columns", "DAY_ID", {"JOB_ID", "DAY_ID"})
in
    #"Expanded DAY_ID"

You may want to group by Job_ID and choose to aggregate max Day_ID

edit: (see below comment) matching against original list allows to keep duplicates of Job_ID with same max Day_ID