How to make formula field for salesforce field?

user_13739576 0
Viewed 3575

I am trying to make formula field for the salesforce field. the condition is given below.

if Company = "WIL" And (ShippingCountry = "United States" Or "USA") then
   "US"
elseif Company = "WST" And (ShippingCountry = "United States" Or "US") then
   "USA"
elseif ShippingCountry <> "" then
   ShippingCountry
elseif Company = "WIL" then
   "US"
elseif Company = "WST" then
   "USA"
else
   ""
end if
crm salesforce if-statement
1 Answers

The trailheads are always a good start. I would suggest Use Formula Fields and Advanced Formulas.
The documentation pages about Formula Operators and Functions might be useful too.

Keep in mind that you must use fields API Names, not labels, so it's Company__c.
If Company__c is not a picklist field:

IF( AND(Company__c = 'WIL', OR(ShippingCountry = 'United States', ShippingCountry = 'USA')),
    'US',
    IF( AND(Company__c = 'WST', OR(ShippingCountry = 'United States', ShippingCountry = 'US')),
        'USA',
        IF( NOT( ISBLANK(ShippingCountry) ),
            ShippingCountry,
            IF( Company__c = 'WIL',
                'US',
                IF(Company__c = 'WST', 'USA', '') 
            ) 
        ) 
    ) 
)

If Company__c is a picklist field you should use ISPICKVAL(picklist_field, literal_value), so the formula would be:

IF( AND( ISPICKVAL(Company__c, 'WIL'), OR(ShippingCountry = 'United States', ShippingCountry = 'USA')),
    'US',
    IF( AND(ISPICKVAL(Company__c, 'WST'), OR(ShippingCountry = 'United States', ShippingCountry = 'US')),
        'USA',
        IF( NOT( ISBLANK(ShippingCountry) ),
            ShippingCountry,
            IF( ISPICKVAL(Company__c, 'WIL'),
                'US',
                IF( ISPICKVAL(Company__c, 'WST'), 'USA', '') 
            ) 
        ) 
    ) 
)
user_86820680
Related