How to get default GCP project and region with Terraform?

user_122727 0
Viewed 1556

For a standard tf boilerplate:

provider "google" {}

How do I get what is the provider's default project and region? Something analogous to aws_region in AWS (like in this question), but for Google Compute Engine (GCE/GCP).

In some cases these are specified externally in the environment variables:

export GOOGLE_PROJECT=myproject
export GOOGLE_REGION=europe-west2
terraform apply

Less often they are overridden in hcl code:

provider "google" {
  project = "myproject"
  region  = "europe-west2"
}

This fails with A managed resource "provider" "google" has not been declared in the root module.:

output "region" {
  value = provider.google.region
}
terraform-provider-gcp terraform google-cloud-platform
1 Answers

Basic

Use the google_client_config data source:

data "google_client_config" "this" {}

output "region" {
  value = data.google_client_config.this.region
}

output "project" {
  value = data.google_client_config.this.project
}

Mutliple providers

This can be used even with multiple providers:

provider "google" {
  region = "europe-west2"
}

provider "google" {
  alias  = "another" // alias marks this as an alternate provider
  region = "us-east1"
}

data "google_client_config" "this" {
  provider = google
}

data "google_client_config" "that" {
  provider = google.another
}

output "regions" {
  value = [data.google_client_config.this.region, data.google_client_config.that.region]
}

Output:

$ terraform init
$ terraform apply --auto-approve

Apply complete! Resources: 0 added, 0 changed, 0 destroyed.

Outputs:

regions = [
  "europe-west2",
  "us-east1",
]
user_1227270
Related