custom order by only printing last value

user_2730554 0
Viewed 53

I have the script below. It only prints out one value, PLGG not all of them.

 Pot

 ABC
 MPOT
 NVPN
 PLGG

However when I remove the order by case section then it prints all of the values. Why is that? Is it no possible to use a custom order by here?

declare @pot nvarchar(max) = ''

select @pot = @pot + QUOTENAME(pot) + ',' 
from myTbl
group by pot
order by case when pot = 'MPot' then '1'
else pot end

print(@pot)
sql-server-2012 sql-server sql
3 Answers

If you're trying to create a delimited list, there are "better" ways. If you're using 2017+, you can use STRING_AGG:

CREATE TABLE dbo.myTbl (Pot varchar(4));

INSERT INTO dbo.myTbl (Pot)
VALUES('ABC'),
      ('MPOT'),
      ('NVPN'),
      ('PLGG');
GO
DECLARE @Pot nvarchar(MAX)

SET @Pot = (SELECT STRING_AGG(QUOTENAME(Pot), ',') WITHIN GROUP (ORDER BY CASE WHEN Pot = 'MPot' THEN '1' ELSE Pot END) FROM dbo.myTbl);

PRINT @Pot;

If you're on 2016-, then you can use FOR XML PATH:

DECLARE @Pot nvarchar(MAX);

SET @Pot = STUFF((SELECT ',' + QUOTENAME(Pot)
                  FROM dbo.myTbl
                  ORDER BY CASE WHEN Pot = 'MPot' THEN '1' ELSE Pot END
                  FOR XML PATH(N''), TYPE).value('.', 'nvarchar(MAX)'),1,1,'');
user_20299830

I can only imagine that you are trying to concatenate the values in a determined order. I recommend:

declare @pot nvarchar(max) = '';

select @pot = string_agg( pot, ',') within group (order by case when pot = 'MPot' then '1' else pot end) 
from (select distinct pot from myTbl) t;

print @pot;
user_11440350

Here is my Solution

declare @mytbl as table(pot nvarchar(max),n int)
insert into @mytbl values('',0),('ABC',0),('MPOT',-1),('NVPN',0),('PLGG',0)



declare @pot nvarchar(max) = ''

select @pot = @pot + QUOTENAME(pot) + ',' 
from @mytbl
group by pot,n
order by n--case when pot = 'MPot' then '1'else pot end
print(@pot)
user_67745060
Related