In F#, is it possible to implement operators for tuples?

user_1256041 0
Viewed 245

I am working with an API that represents points like float * float.

These are inconvenient to do arithmetic on: 

let a = (3.0, 4.0)
let b = (2.0, 1.0)

let c = (fst a + fst b, snd a + snd b)

I would like to write: 

let c = a + b

I can do this if I define my own type: 

type Vector2 =
  {
    X : float;
    Y : float;
  }
  with
    static member (+) (a : Vector2, b : Vector2) =
      { X = a.X + b.X; Y = a.Y + b.Y }

But then I need to convert for the API I am using: 

let c = a + b
let cAsTuple = (c.X, c.Y)

Alternatively, I could create a free function: 

let add (ax, ay) (bx, by) = 
  (ax + bx, ay + by)

let c = a |> add b

But this is not quite as nice as true infix operators.

Does F# allow me to define custom operators for tuples?

f#
2 Answers

If you are willing to use a different operator like (+.) you can do this:

let inline (+.) (a,b) (c,d) = (a + c, b + d)

it works with ints, floats, strings:

( 4 ,  3 ) +. ( 3 ,  2 ) // (7, 5)
( 4.,  3.) +. ( 3.,  2.) // (7.0, 5.0)
("4", "3") +. ("3", "2") // ("43", "32")
user_45508980

TL;DR; @AMieres answer is the real one, this should rather be a comment but comments are length limited and code formatting is not nice ¯_(ツ)_/¯

There is work in progress to make operator extensions become reality: Issue, RFC, PR Once this is done, the following might finally work:

open System
open System.Runtime.CompilerServices

[<Extension>]
type TupleExtensions() =
    [<Extension>]
    static member inline (+) ((x1, y1), (x2, y2)) = (x1 + x2, y1 + y2)

// or

type Tuple<'T1, 'T2> with
    // warning FS1215: Extension members cannot provide operator overloads.
    // Consider defining the operator as part of the type definition instead.
    static member inline (+) ((x1, y1), (x2, y2)) = (x1 + x2, y1 + y2)

// and then

let t1 = (1., 2.)
let t2 = (42., 3.141)

TupleExtensions.(+) (t1, t2) // (43.0, 5.141)

// error FS0001: Expecting a type supporting the operator '+' but given a tuple type
t1 + t2
user_28947700
Related