Move entire line up and down in Vim

If I want to swap one line with the line above I usually do the following

ddkP

Explanation

• dd will delete the line and add it to the default register.
• k will move up a line (j would move down a line)
• P will paste above the current line

Put the following to your .vimrc to do the job

noremap <c-s-up> :call feedkeys( line('.')==1 ? '' : 'ddkP' )<CR>
noremap <c-s-down> ddp

Disappearing of the line looks like a Vim bug. I put a hack to avoid it. Probably there is some more accurate solution.

Update

There are a lot of unexplained difficulties with just using Vim combinations. These are line missing and extra line jumping.

So here is the scripting solution which can be placed either inside .vimrc or ~/.vim/plugin/swap_lines.vim

function! s:swap_lines(n1, n2)
    let line1 = getline(a:n1)
    let line2 = getline(a:n2)
    call setline(a:n1, line2)
    call setline(a:n2, line1)
endfunction

function! s:swap_up()
    let n = line('.')
    if n == 1
        return
    endif

    call s:swap_lines(n, n - 1)
    exec n - 1
endfunction

function! s:swap_down()
    let n = line('.')
    if n == line('$')
        return
    endif

    call s:swap_lines(n, n + 1)
    exec n + 1
endfunction

noremap <silent> <c-s-up> :call <SID>swap_up()<CR>
noremap <silent> <c-s-down> :call <SID>swap_down()<CR>

This worked for me:

http://vim.wikia.com/wiki/Moving_lines_up_or_down_in_a_file

BTW, if you want to use ALT+some_key and your terminal (urxvt does this) refuses to comply, you should enter something like this in your .vimrc:

" For moving lines (^] is a special character; use <M-k> and <M-j> if it works)
nnoremap ^]k mz:m-2<CR>`z==
inoremap ^]j <Esc>:m+<CR>==gi
inoremap ^]k <Esc>:m-2<CR>==gi
vnoremap ^]j :m'>+<CR>gv=`<my`>mzgv`yo`z
nnoremap ^]j mz:m+<CR>`z==
vnoremap ^]k :m'<-2<CR>gv=`>my`<mzgv`yo`z

where ^] is a single character that represents the ALT key. To input that character, use C+v, Esc in Vim (C+q, Esc on Windows).

Easiest way same like vscode. Add below line to .vimrc

"Ctrl+Shift+up move line above"
nmap <C-S-Up> :m -2<CR>

"Ctrl+Shift+down move line below
nmap <C-S-Down> :m +1<CR>

When you hit command :help move in vim, here is the result:

:[range]m[ove] {address} *:m* *:mo* *:move* *E134* Move the lines given by [range] to below the line given by {address}.

E.g: Move current line one line down => :m+1.

E.g: Move line with number 100 below the line with number 80 => :100 m 80.

E.g: Move line with number 100 below the line with number 200 => :100 m 200.

E.g: Move lines with number within [100, 120] below the line with number 200 => :100,120 m 200.

For me, ddkkp did it (instead of ddkP with an uppercase P, which would work too).

Here is a solution that works on my machine : MacBook Pro running VIM 8.1

These commands will not delete your lines at the top or bottom of your buffer.

Using the actual symbols that Alt-J and Alt-K output is a workaround for their key-codes not mapping properly in my environment.

Throw this in the old .vimrc and see if works for you.

" Maps Alt-J and Alt-K to macros for moving lines up and down
" Works for modes: Normal, Insert and Visual
nnoremap ∆ :m .+1<CR>==
nnoremap ˚ :m .-2<CR>==
inoremap ∆ <Esc>:m .+1<CR>==gi
inoremap ˚ <Esc>:m .-2<CR>==gi
vnoremap ∆ :m '>+1<CR>gv=gv
vnoremap ˚ :m '<-2<CR>gv=gv

Your cursor can be on any line. Line numbers are turned on to easily identify line locations.
1st case: Say I'm on line #7 and want to move line #3 to line #9 bring it down the page.

• :3m 9 completes the move.

2nd case: I'm still on line #7 but now I want to move line #9 to line #3 bring it up the page.

• :9m 2 completes the move. Note the use of 2 for the destination instead of 3.

Note: the cursor will move to the move destination location. If I want are need to go back to line #7 simply use :7

3rd case: move a range of lines. Say, 9 thru 12 where line 9 ends up on on line 3

• :9,12m 2 completes the move. image of: A terminal playpen with Vim open for move experimenting

In case you want to do this on multiple lines that match a specific search:

• Up: :g/Your query/ normal ddp or :g/Your query/ m -1
• Down :g/Your query/ normal ddp or :g/Your query/ m +1

can use command:

:g/^/move 0

reference: https://vi.stackexchange.com/questions/2105/how-to-reverse-the-order-of-lines